Adapt ColorFunction in Array Plot

Question

The problem I'm facing is how to adapt ColorFunction so that it ranges from green (low values) to red (high values):

ArrayPlot[{a1, a2, a3, a4, a5}, ColorFunction -> (* ??? *)]

Answer 1

ArrayPlot[RandomReal[1, {10, 10}], 
 ColorFunction -> (Blend[{Green, Red}, #] &)]

If you need to specify a more specific range of colors:

ArrayPlot[RandomReal[1, {10, 10}], 
 ColorFunction -> (Blend[{{0, Darker[Green]}, {.25, Green}, {.5, 
 Yellow}, {.75, Orange}, {1, Red}}, #] &)]

Answer 2

Here are some data:

data = Table[x + Sin[3 x + y^2], {x, -3, 3, .01}, {y, -3, 3, .01}];

In Mathematica there are designated so called Color Schemes. For example in your case you could use "RoseColors":

ArrayPlot[data, ColorFunction -> "RoseColors"]

But I personally would go with "TemperatureMap" as good indicator of low/high values. Another way to is to use Hue with modified argument to get green-red for start-end of the scale:

ArrayPlot[{Range[0, 1, .01]}, AspectRatio -> 1/4, ColorFunction -> (Hue[.8 (# + .3)] &)]

Answer 3

This works:

ArrayPlot[Array[BitXor, {64, 64}, {0, 0}], ColorFunction -> (RGBColor[#, 1 - #, 0] &)]

---

Here's a little utility function for automatically generating a color function that linearly interpolates between two colors:

linearColorFunction[colMin_, colMax_] := Function[Evaluate[RGBColor @@ MapThread[
      Expand[InterpolatingPolynomial[{{0, #1}, {1, #2}}, \[FormalX]]] &,
      List @@@ (ColorConvert[#, RGBColor] & /@ {colMin, colMax})] /. \[FormalX] -> #]]

Examples:

linearColorFunction[Green, Red] (* OP's example *)
RGBColor[#1, 1 - #1, 0] &

linearColorFunction[Cyan, Magenta] (* "cool" colormap in MATLAB *)
RGBColor[#1, 1 - #1, 1] &

As already noted, the function generated by linearColorFunction[colMin, colMax] behaves the same way as the function Blend[{colMin, colMax}, #].