Export Table from Mathematica into specific cells Excel

Question

How can I export a table to Excel - to specific cells, e.g. D1-E2?

Background: I want to compare results, and it's easier to have the results on one spreadsheet.

I'm using Mathematica 6.

This is my notebook so far:

ResultsV = Grid[{  {"result1", result1},  {"result2", result2}}] 
Export["results.pdf", ResultsV]

This table should appear twice in the spreadsheet, as some parameters differ.

Thanks a lot!

Answer 1

For example:

(* some data *)
pts = Range[10]^4;
f1 = Interpolation[pts, InterpolationOrder -> 1];
f2 = Interpolation[pts, InterpolationOrder -> 3];
t1 = Join[{{"x", "f1[]"}}, Table[{x, f1@x}, {x, 1.5, 4.5, 1}]];
t2 = Join[{{"x", "f2[]"}}, Table[{x, f2@x}, {x, 1.5, 4.5, 1}]];
data = Join @@@ Transpose@{t1, t2};

(* Transformation from Excel "A1" notation to indexes *)
at = {FromDigits@ToExpression@Flatten[StringCases[Characters[#], _?DigitQ], 1], 
      FromDigits[Flatten[ToCharacterCode /@ StringCases[Characters[#], _?UpperCaseQ] - 
       First@ToCharacterCode["A"] + 1, 2], Length@CharacterRange["A", "Z"]]} &;

(* Generation of a sparse array with the required block positioning *)
sp[data_List, pos_String] := SparseArray[
                              Flatten@MapIndexed[#2 + at@pos - 1 -> #1 &, data, {2}],  
                            Automatic, ""];

(* export the data to Excel*)
Export["c:\\test2.xls", sp[data, "B3"]]