Mathematica function intersection points with 3D grid

Question

I need to produce a 3-dimensional equispaced grid over a given function in a way, that I can calculate intersection points of the function with the grids edges. So my first question is how to produce this grid in Mathematica. I don't really get if this is possible by modeling the grid by Polygons? For this I might need some help then, too. Or can it be done by using more simple graphics objects like done here?

Answer 1

Do I understand it correctly that you are looking for the intersection of an implicitly defined surface with planes (planes that could make up a grid)?

Suppose we have this surface ...

j = 1.25;

ContourPlot3D[
 x^4 + y^4 + z^4 - (x^2 + y^2 + z^2) == -2/5, 
  {x, -j, j}, {y, -j, j}, {z, -j, j}, 
 Mesh -> False, Axes -> False, PlotPoints -> 30]

... and we want to visualize the intersection with the plane $x + 2y - z$:

ContourPlot3D[x + 2 y - z == 0, {x, -j, j}, {y, -j, j}, {z, -j, j}, 
 Axes -> False]

The simplest way is to use custom MeshFunctions with ContourPlot3D:

gr =ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2) == -2/5, 
   {x, -j, j}, {y, -j, j}, {z, -j, j}, 
   Axes -> False, PlotPoints -> 30,
   MeshFunctions -> {Function[{x, y, z}, x + 2 y - z]}, 
   Mesh -> {{0.}}, MeshStyle -> Thick]

Or take the intersections with planes parallel to $yz$:

Update: You can extract the coordinates for the points making up the lines like this: Cases[Normal[gr], _Line, Infinity].

Answer 2

Here's an answer to my interpretation of the question:

Start with a three dimensional grid of lines:

lines = With[{j = 1.25, h = 0.25}, {
  Table[Line[{{x, y, -j}, {x, y, j}}], {x, -j, j, h}, {y, -j, j, h}],
  Table[Line[{{x, -j, z}, {x, j, z}}], {x, -j, j, h}, {z, -j, j, h}],
  Table[Line[{{-j, y, z}, {j, y, z}}], {y, -j, j, h}, {z, -j, j, h}]
}];

Turn each line into rule which gives a parameterisation of the line:

rules = Flatten[lines] /. Line[{{ax_, ay_, az_}, {bx_, by_, bz_}}] ->
  {x -> ax + t (bx - ax), y -> ay + t (by - ay), z -> az + (bz - az)};

Now solve t in whatever implicit equation you have, and extract the valid solution points:

points = Cases[{x, y, z} /. # /. NSolve[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2) == -2/5 /. #,
 t, Reals] & /@ rules, {_?NumberQ, _?NumberQ, _?NumberQ}, Infinity];

And plot the results:

Graphics3D[{PointSize[0.015], Point[points], Opacity[0.25], lines}, Boxed -> False]

Answer 3

From your description, it seems that you need to find the points of intersection between a set of lines and your function, the lines being part of your "grid."

When you say intersection with the grid's edges, I am assuming that you mean points on the grid lines in the following sense: each grid unit makes cube of regular dimensions. You want to determine the intersection of the function with cube faces.

If this is the case, all you need to do is solve for intersection with sets of plane equations.