If I know the steady state vector of a stochastic matrix, can i recover the matrix? [closed]

Question

By steady state vector I mean the eigenvector which has an eigenvalue of 1. So is there a way to at least iteratively approximate the entries of the stochastic matrix?

Thanks.

Answer 1

To elaborate on my comment, here is a 3x3 example. We treat the eigenvector components as parameters, and show that there is a nonunique solution set for the matrix components in terms of these parameters. My comment was off by one insofar as I neglected to normalize the eigenvector. Since generically the components will not sum to zero, I simply set their sum to unity for that purpose.

In[41]:= mat = Array[a, {3, 3}];
evec = Array[x, 3];
eqns = Join[Thread[Total[Transpose[mat]] == 1], 
  Thread[mat.evec == evec], {Total[evec] == 1}]

Out[43]= {a[1, 1] + a[1, 2] + a[1, 3] == 1, 
 a[2, 1] + a[2, 2] + a[2, 3] == 1, a[3, 1] + a[3, 2] + a[3, 3] == 1, 
 a[1, 1] x[1] + a[1, 2] x[2] + a[1, 3] x[3] == x[1], 
 a[2, 1] x[1] + a[2, 2] x[2] + a[2, 3] x[3] == x[2], 
 a[3, 1] x[1] + a[3, 2] x[2] + a[3, 3] x[3] == x[3], 
 x[1] + x[2] + x[3] == 1}

Now we solve the system, only allowing one parameter equation so as to ignore lower dimensional solution sets that arise when there something more than the normalization condition is imposed on the eigenvector parameters.

In[48]:= Solve[eqns, Flatten[mat], MaxExtraConditions -> 1]

During evaluation of In[48]:= Solve::svars: Equations may not give
  solutions for all "solve" variables. >>

Out[48]= {{a[1, 2] -> 
   ConditionalExpression[((-1 + a[1, 1]) (-1 + x[2] + 2 x[3]))/(
    x[2] - x[3]), x[1] + x[2] + x[3] == 1], 
  a[1, 3] -> 
   ConditionalExpression[-(((-1 + a[1, 1]) (-1 + 2 x[2] + x[3]))/(
     x[2] - x[3])), x[1] + x[2] + x[3] == 1], 
  a[2, 2] -> 
   ConditionalExpression[(-a[2, 1] + x[2] + a[2, 1] x[2] - x[3] + 
     2 a[2, 1] x[3])/(x[2] - x[3]), x[1] + x[2] + x[3] == 1], 
  a[2, 3] -> 
   ConditionalExpression[-((a[2, 1] (-1 + 2 x[2] + x[3]))/(
     x[2] - x[3])), x[1] + x[2] + x[3] == 1], 
  a[3, 2] -> 
   ConditionalExpression[(a[3, 1] (-1 + x[2] + 2 x[3]))/(x[2] - x[3]),
     x[1] + x[2] + x[3] == 1], 
  a[3, 3] -> 
   ConditionalExpression[(
    a[3, 1] + x[2] - 2 a[3, 1] x[2] - x[3] - a[3, 1] x[3])/(
    x[2] - x[3]), x[1] + x[2] + x[3] == 1]}}

One will observe that the solution set is not fully determined, in that six matrix entries are functions of the remaining three. (Why three undetermined values? We had nine variables and seven equations, but one eigenvector equation is linearly dependent on the stochasticity and the other two such equations. So we only have six independent equations.)

I guess the short answer would be "No".