How can I assign a Fit result to a function?

Question

I have this code

ntcrr[t_] := E^(a + b/t + c/t^2 + d/t^3)
kelvin[t_] := t + 273.15
a = -13.40956889; b = 4481.798865; c = -150521.6916; d = 1877102.652;
p1 = {30, ntcrr[kelvin[30]]}; p2 = {35, ntcrr[kelvin[35]]};
line := Fit[{p1, p2}, {1, x}, x]

{ 1.67709 - 0.0285019 x }

Then I plug in this function in my Plot

Plot[ntcrr[kelvin[t]]/(1.67709 - 0.0285019 t), {t, 30, 35}]

and that works, but I'd rather like to assign the Fit result to a function, like this:

line[x_] := Fit[{p1, p2}, {1, x}, x]
Plot[ntcrr[kelvin[t]]/line[t], {t, 30, 35}]

but that doesn't work. How can I assign a Fit result to a function?

Answer 1

Use Set[] (=) instead of SetDelayed[] (:=) on the output of Fit[], like so:

line[x_] = Fit[{p1, p2}, {1, x}, x];

Plot[ntcrr[kelvin[t]]/line[t], {t, 30, 35}]

---

Addendum by Mr. Wizard

You may wish to localize the variable in this construct, so that the creation of the definition is safe from a global assignment. Here are two ways of achieving this:

• Block

  Block[{x},
        f[x_] = Fit[{p1, p2}, {1, x}, x]
        ]
  

• Formal Symbols (looks better in a notebook):

  f[\[FormalX]_] = Fit[{p1, p2}, {1, \[FormalX]}, \[FormalX]]
  

Answer 2

If, for any conceivable reason, you want to preserve the SetDelayed (:=), you might want to try

line2 := Function[{y}, Evaluate[Fit[{p1, p2}, {1, y}, y]]]
Plot[ntcrr[kelvin[t]]/line2[t], {t, 30, 35}, Evaluated -> True]