Using a Slider to manipulate a Plot

Question

Why does this work (displays the curve):

Graphics[Plot[Sin[x], {x, 0, Pi}]]

and this doesn't (no curve)

Graphics[Plot[Sin[a x], {x, 0, Pi}], {Slider[a, 0, 4]}]

?

I would like to work without Manipulate.

Answer 1

You can make the slider to appear as part of the plot:

Overlay[{
  Dynamic@Plot[Sin[a x], {x, 0, Pi}, PlotRange -> {{0, Pi}, {-1, 1}},Frame -> True],
  Panel@VerticalSlider[Dynamic[a], {1, 9}, ImageSize -> {15, 60}]
  }, All, 2, Alignment -> {.9, .8}]

And even develop something more elaborate like this:

Overlay[{
  Dynamic@Plot[Sin[a x], {x, 0, Pi}, PlotRange -> {{0, Pi}, {-1, 1}}, 
    Frame -> True, PlotStyle -> Thick],
  Framed[Row[{Graphics[{}, PlotRange -> {{0, 1}, {1, 9}}, 
      Frame -> {{False, True}, {False, False}}, 
      FrameTicks -> {None, Range[9]}, ImageSize -> 20],
     VerticalSlider[Dynamic[a], {1, 9}, ImageSize -> {20, 95}, 
      Appearance -> "LeftArrow"]
     }], FrameMargins -> 0, 
   Background -> Directive[Black, Opacity[.2]], RoundingRadius -> 6]
  }, All, 2, Alignment -> {.9, .8}]

Answer 2

It doesn't work for a few reasons:

• The syntax for Slider is not correct. It should be Slider[a, {0, 4}]
• The variable a needs to by Dynamic so that it is updated when you move the slider.
• Slider is not a graphics primitive.

Additionally, you don't need the Graphics and it is a good idea to localize the dynamic variable using DynamicModule. I would suggest something like:

DynamicModule[{a}, 
    Column[{
        Dynamic@Plot[Sin[a x], {x, 0, Pi}, PlotRange -> {All, {-1, 1}}], 
        Slider[Dynamic@a, {0, 4}]
    }]
]

You need to set PlotRange so that the figure doesn't jump around when you move the slider.