# Strange result when integrating BesselJ functions

Consider the following integral:

FullSimplify[Integrate[r BesselJ[m,BesselJZero[m,n]r /a]^2,{r,0,a}],
Assumptions->n\[Element]Integers&&n>=1&&m\[Element]Integers]
(* ConditionalExpression[1/2 a^2 BesselJ[-1+m,BesselJZero[m,n]]^2,m>-1] *)


This gives part of the orthogonality condition of BesselJ functions (see here, Eq. 53). What I can't figure out is the reason for the ConditionalExpression. Mathematica knows about the relationship:

FullSimplify[BesselJ[-m,x]==(-1)^m BesselJ[m,x],Assumptions->m\[Element]Integers]
(* True *)


and can even calculate the integral given m=-1, for example, explicitly:

Integrate[r BesselJ[-1, BesselJZero[-1, n] r /a]^2, {r, 0, a}]
(* 1/2 a^2 (BesselJ[0,BesselJZero[-1,n]]^2+BesselJ[1,BesselJZero[-1,n]]^2-
(2 BesselJ[0,BesselJZero[-1,n]] BesselJ[1,BesselJZero[-1,n]])/BesselJZero[-1,n]) *)


But, trying to force Integrate to assume m<=-1 throws an error:

Integrate[r BesselJ[m,BesselJZero[m,n]r /a]^2,{r,0,a},
Assumptions->n\[Element]Integers&&n>=1&&m\[Element]Integers&&m<=-1]
(* Integrate::idiv: Integral of r BesselJ[m,(r BesselJZero[m,n])/a]^2
does not converge on {0,a}.*)


So, why can't it solve it for any (integer) m in the first (or negative integers in the last) scenario?

Edit Additional strangeness based on belisarius's comment. If you directly integrate something like:

Integrate[r BesselJ[15,BesselJZero[15,n] r/a]^2,{r,0,a},Assumptions->n\[Element]Integers&&n>=1]


it outputs a giant monstrosity. Yet, this monstrosity is (nearly) equivalent to the smaller expression:

N[(% /. n -> 1)]-
N[(1/2 a^2 BesselJ[-1 + 15, BesselJZero[15, n]]^2 /. n -> 1)]
(* 6.12357*10^-16 a^2 *)


It seems that it uses a different method for integrating these functions with an explicit value for m than without. And for some reason doesn't use the (-1)^m BesselJ identity for solving the m<=-1 cases.

Edit 2 Based on J.M.'s answer this gets stranger. First of all, integrating:

Integrate[r BesselJ[m,BesselJZero[m,n] r/a]^2,{r,0,a},
Assumptions->n\[Element]Integers&&Positive[n]&&m\[Element]Integers&&Negative[m]]


works fine. As does,

Integrate[r BesselJ[m,BesselJZero[m,n] r/a]^2,{r,0,a},
Assumptions->n\[Element]Integers&&n>=1&&m\[Element]Integers&&Negative[m]]


and even

Integrate[r BesselJ[m,BesselJZero[m,n] r/a]^2,{r,0,a},
Assumptions->n\[Element]Integers&&n>=1&&m\[Element]Integers&&m<0]


But,

Integrate[r BesselJ[m,BesselJZero[m,n] r/a]^2,{r,0,a},
Assumptions->n\[Element]Integers&&n>=1&&m\[Element]Integers&&m<=-1]


fails with the error from above.

Furthermore, even though

Integrate[r BesselJ[m,BesselJZero[m,n] r/a]^2,{r,0,a},
Assumptions->n\[Element]Integers&&n>=1&&m\[Element]Integers&&Negative[m]]==
Integrate[r BesselJ[m,BesselJZero[m,n] r/a]^2,{r,0,a},
Assumptions->n\[Element]Integers&&Positive[n]&&m\[Element]Integers&&Positive[m]]

(* True *)


the timing to solve these are way different. With

Integrate[ snip Positive[m]];//Timing
Integrate[ snip Negative[m]];//Timing

(* {15.538, Null}
{0.421, Null} *)


which is a huge increase in time for essentially the same integral. Any further ideas?

-
try Integrate[r BesselJ[m, BesselJZero[m, n] r/a]^2, {r, 0, a}, Assumptions -> n \[Element] Integers && n >= 1 && m \[Element] Integers && m == -15] and take a look at those coefficients –  belisarius Jul 6 '12 at 18:49
@belisarius But you get the same mess using m==15. Yet, it can also be expressed as 1/2 a^2 BesselJ[-1 + 15, BesselJZero[15, n]]^2. –  Eli Lansey Jul 6 '12 at 19:01

While trying to investigate this, I hit upon the following integral:

Integrate[BesselJ[Floor[m], r]^2, {r, 0, 1}, Assumptions -> m <= -1]


0

This is obviously an incorrect result. It only appears when I add the assumption above. This leads me to suspect that the failure of Eli's integral in the same range of m is related to this - and I'd call it a bug that needs to be reported.

Edit

I did report that error in 2012 [TS 26556], but got the reply that it's expected behavior. The argument for this claim given in their initial reply was that this is equivalent to specifying m to be an integer, which is a non-generic case that gets ignored. However, the non-generic case here would not yield a result 0 for the integral with non-integer and negative m, so the behavior shouldn't be expected at all.

He also said: "Using Floor is an interesting way to restrict the evaluation to integer values of the parameter and Integrate doesn't appear to be handling it well, so I've forwarded the example to our developers."

Unfortunately, I didn't hear back, and the bug hasn't been fixed as of version 10.1.

-

Apparently, what you should be doing is

Integrate[r BesselJ[m, BesselJZero[m, n] r/a]^2, {r, 0, a},
Assumptions -> n \[Element] Integers && Positive[n] &&
m \[Element] Integers && Negative[m]]

1/2 a^2 (BesselJ[m, BesselJZero[m, n]]^2 + BesselJ[1 + m, BesselJZero[m, n]]^2 -
(2 m BesselJ[m, BesselJZero[m, n]] BesselJ[1 + m, BesselJZero[m, n]])/BesselJZero[m, n])


Sometimes, people forget that Positive[]/Negative[]/NonNegative[]/NonPositive[] are usable as assumptions.

-
I've updated the question with some further questions that arise from this answer. –  Eli Lansey Jul 12 '12 at 14:24