Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

What is the command to find function invariant?

http://demonstrations.wolfram.com/AFunctionInvariantUnderAGroupOfTransformations/

what is algorithm it use to calculate this?

Edit

there is a book do it in this way

Hope this book give you an idea on how to do multivariate case

share|improve this question
2  
You can download / preview the source code on the right of the page... apart from that, your question does not seem very attractive / concise yet. Have a look at the FAQ. –  Yves Klett Jul 2 '12 at 10:57
    
@YvesKlett The code does not find the invariant, it just plots it –  belisarius Jul 2 '12 at 12:10
    
@belisarius Acknowledged... –  Yves Klett Jul 2 '12 at 12:29
add comment

2 Answers

up vote 9 down vote accepted

The Wolfram Demonstration in its original version was wrong. The demo has since been corrected (updated March 2013). The first five functions called $H$ there (which were originally the only functions listed) do not form a group. You need a sixth element to make the set closed under multiplication!

This can be checked by defining the six functions as follows, with the missing element as the last function. I call the table of functions h, and then construct the multiplication table:

h = {# &, 1/# &, 1 - # &, 1/(1 - #) &, (# - 1)/# &, #/(# - 1) &};

TableForm[multiplicationTable = Table[
   Simplify[
    h[[i]][h[[j]][x]]
    ],
   {i, 1, 6}, {j, 1, 6}
   ]
 ]

$\left( \begin{array}{cccccc} x & \frac{1}{x} & 1-x & \frac{1}{1-x} & \frac{x-1}{x} & \frac{x}{x-1} \\ \frac{1}{x} & x & \frac{1}{1-x} & 1-x & \frac{x}{x-1} & \frac{x-1}{x} \\ 1-x & \frac{x-1}{x} & x & \frac{x}{x-1} & \frac{1}{x} & \frac{1}{1-x} \\ \frac{1}{1-x} & \frac{x}{x-1} & \frac{1}{x} & \frac{x-1}{x} & x & 1-x \\ \frac{x-1}{x} & 1-x & \frac{x}{x-1} & x & \frac{1}{1-x} & \frac{1}{x} \\ \frac{x}{x-1} & \frac{1}{1-x} & \frac{x-1}{x} & \frac{1}{x} & 1-x & x \\ \end{array} \right)$

To see that this table would be incomplete without the last function $x/(x-1)$, look at the element {2, 5} in the table: it is not equal to any of the first five functions.

Now to answer the question of how to construct a function that is invariant under this (corrected) group.

This is done in group theory using projection operators. Here we're only interested in the simplest (identity) representation of the group, for which the projector consists of adding all the group actions on an arbitrary trial function and dividing by the order n of the group $\mathcal{G}$. Here is the formula in mathematical notation and then as a Mathematica definition:

$$f_\text{sym}(x)\equiv \frac{1}{n}\sum_{H\in \mathcal{G}} f(H(x)) $$

symmetrize[f_] :=
 With[{n = Length[h]},
  Function[{x},
   1/n Total@Map[Composition[f, #][x] &, h]
   ]
  ]

Here f is the trial function, and the simplest choice is

f[x_] := x;
fSym = symmetrize[f];    
fSym[x] 

$\frac{1}{6} \left(\frac{x-1}{x}+\frac{1}{1-x}+\frac{1}{x}+\frac{x} {x-1}+1\right)$

Check that this is indeed an invariant function:

Table[
  Simplify[fSym[h[[i]][x]] == fSym[h[[j]][x]]],
  {i, 1, 6}, {j, 1, 6}] // TableForm

$\left( \begin{array}{cccccc} \text{True} & \text{True} & \text{True} & \text{True} & \text{True} & \text{True} \\ \text{True} & \text{True} & \text{True} & \text{True} & \text{True} & \text{True} \\ \text{True} & \text{True} & \text{True} & \text{True} & \text{True} & \text{True} \\ \text{True} & \text{True} & \text{True} & \text{True} & \text{True} & \text{True} \\ \text{True} & \text{True} & \text{True} & \text{True} & \text{True} & \text{True} \\ \text{True} & \text{True} & \text{True} & \text{True} & \text{True} & \text{True} \\ \end{array} \right)$

Now the real fun starts if you choose different trial functions f.

f[x_] := Exp[x - x^2]
fSym = symmetrize[f];
Simplify[fSym[x]]

$\frac{1}{3} \left(e^{\frac{x-1}{x^2}}+e^{x-x^2}+e^{-\frac{x}{(x-1) ^2}}\right)$

And believe it or not, this is also an invariant function. To verify, repeat the check I did above.

Edit: check the given invariant function

We can also verify that the function that is given in the Wolfram demonstration is indeed one of the possible invariant functions, by showing that it is mapped onto itself by the projection operator symmetrize:

invariant1[x_] := (x^2 - x + 1)^3/(x^2 (x - 1)^2)

Simplify[symmetrize[invariant1][x] == invariant1[x]]

(* ==> True *)
share|improve this answer
    
without your explanation, i guess this will take a whole life to try –  M-Askman Jul 3 '12 at 14:42
add comment

Not a general solution, but works for the case you cited;

(*Definitions*)
an=6;
bn=4;
h[0,x_]:=x;     h[1,x_]:=1/x;  
h[2,x_]:=1-x;   h[3,x_]:=1/(1-x);  h[4,x_]:=(x-1)/x;
f[x_] := Sum[a@i x^i,{i,an}] / Sum[b@i x^i,{i,bn}];  (*Proposed form / Rational*)

(*Now find the coefficients a[i] and b[i]*)
ss=Solve[And @@ Table[f@h[i,x] == f@x,{i,0,4}], Join[Array[a,an],Array[b,bn]]];
(*Get a function from the results set*)
ff[x_] := FullSimplify[f@x/.ss[[1]]/.Table[a@i->1,{i,an}]/.Table[b@i->1,{i,bn}]];

Now test it:

Table[ff@h[i,x] == ff@x, {i, 0, 4}]
ff@x
(*
-> {True, True, True, True, True}
-> 2/(-1 + x) + ((-1 + x)^2 (1 + x + x^2))/x^2
*)
share|improve this answer
    
h[3] should be 1/(1-x) –  Simon Woods Jul 2 '12 at 12:46
    
@SimonWoods Corrected, thanks –  belisarius Jul 2 '12 at 12:48
    
i found a book do it in this way, books.google.com.hk/… –  M-Askman Jul 2 '12 at 13:19
    
in the book, not clear how it works –  M-Askman Jul 2 '12 at 13:20
add comment

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.