Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

This is a spin off/follow up to Can 2D and 3D plots be combined so that the 2D plot is the bottom surface of the 3D plot boundary? ...

Following Sjoerd's method, I did this:

image = Plot[x^2, {x, -2, 2}, PlotStyle -> {Thick, Black}]; 
Show[Graphics3D[{EdgeForm[], Texture[image], 
Polygon[{{-1, -1, -1}, {1, -1, -1}, {1, 1, -1}, {-1, 1, -1}}, 
VertexTextureCoordinates -> {{0, 0}, {1, 0}, {1, 1}, {0, 1}}]}, 
Lighting -> "Neutral", BoxRatios -> {1, 1, .1}], Boxed -> True]

Mathematica graphics

Two questions:

(1) When I click on the cell bracket and save as... PDF, the resulting graphic is either empty or only contains a snippet of the intended graphic.

(2) I would like to have Mathematica draw the solid which has the region bounded by the parabola and the x axis as its base, but with cross-sections (perpendicular to the base) to be squares. I am not sure how to go about this using Graphics3D.

Any ideas?

Edit: RegionPlot3D indeed allows me to answer (2) very quickly:

p1 = Plot[x^2, {x, -2, 2}, PlotStyle -> {Thick, Black}];
p2 = RegionPlot3D[-Sqrt[y] <= x <= Sqrt[y] && 
 0 <= z <= 2 Sqrt[y], {x, -2, 2}, {y, 0, 4}, {z, 0, 4}, 
 Mesh -> False, PlotPoints -> 100, PlotStyle -> Opacity[.3], 
 Boxed -> False, Axes -> False]
p3 = Show[
 Graphics3D[{EdgeForm[], Texture[p1], 
 Polygon[{{-1, -1, -1}, {1, -1, -1}, {1, 1, -1}, {-1, 1, -1}}, 
 VertexTextureCoordinates -> {{0, 0}, {1, 0}, {1, 1}, {0, 1}}]}, 
 Lighting -> "Neutral", BoxRatios -> {1, 1, 1}], Boxed -> True]

Now my only issue is how to lay the solid in p2 over the image in p3? I tried

Show[p2, p3, PlotRange -> All]

and other variations, to no avail.

Edit #2: Should have had RegionPlot z range as {z,0,4}. Fixed now. Also, the slices can be visualized via

slices = Table[RegionPlot3D[-Sqrt[y] <= x <= Sqrt[y] && 0 <= z <= 2 Sqrt[y] && 
 j - .5 <= y <= j, {x, -2, 2}, {y, 0, 4}, {z, 0, 4}, 
 Mesh -> False, PlotPoints -> 100, PlotStyle -> Opacity[.3], 
 Boxed -> False, Axes -> False], {j, .5, 4, .5}];
Show[Table[slices[[j]], {j, 1, 8}]]

share|improve this question
1  
I am having a hard time thinking what but with cross-sections (perpendicular to the base) to be squares. means. Could you upload a hand drawing? –  belisarius Jul 1 '12 at 23:34
    
I can reproduce your PDF problems. Save to EPS doesn't work either, but SVG (also a vector format) works fine. Perhaps that might be a solution. –  Sjoerd C. de Vries Jul 1 '12 at 23:40
    
You've looked at RegionPlot3D[] for your second question? –  J. M. Jul 2 '12 at 0:06
    
@belisarius: Compile this p1 = Plot[x^2, {x, -2, 2}, PlotStyle -> {Thick, Black}]; p2 = Table[ Plot[j/2, {x, -Sqrt[j/2], Sqrt[j/2]}, PlotStyle -> {Thick, Blue}], {j, 1, 8}]; p3 = Show[p1, p2]; Show[Graphics3D[{EdgeForm[], Texture[p3], Polygon[{{-1, -1, -1}, {1, -1, -1}, {1, 1, -1}, {-1, 1, -1}}, VertexTextureCoordinates -> {{0, 0}, {1, 0}, {1, 1}, {0, 1}}]}, Lighting -> "Neutral", BoxRatios -> {1, 1, .1}], Boxed -> True] the blue lines would form the bottom edge of a square. –  JohnD Jul 2 '12 at 0:07
    
Ok. If don't post a (hand)drawing of your desired result, I'll leave this one for others –  belisarius Jul 2 '12 at 0:40
show 1 more comment

1 Answer

up vote 4 down vote accepted

I'm guessing you want something like this:

p1 = Plot[x^2, {x, -2, 2}, PlotStyle -> {Thick, Black}];
p2 = RegionPlot3D[-Sqrt[y] <= x <= Sqrt[y] && 
    0 <= z <= 2 Sqrt[y], {x, -2, 2}, {y, 0, 4}, {z, 0, 2}, 
   Mesh -> False, PlotPoints -> 100, PlotStyle -> Opacity[.3], 
   Boxed -> False, Axes -> False];
p3 = Graphics3D[{EdgeForm[], Texture[p1], 
    Polygon[{{-2, 0, -1}, {2, 0, -1}, {2, 4, -1}, {-2, 4, -1}}, 
     VertexTextureCoordinates -> {{0, 0}, {1, 0}, {1, 1}, {0, 1}}]}];

Graphics3D[{p2[[1]], p3[[1]]}, Lighting -> "Neutral", 
 BoxRatios -> {1, 1, 1}, Boxed -> True]

solid

Here I modified your p3 to make the polygon bigger so its boundaries are described by {{-2, 0, -1}, {2, 0, -1}, {2, 4, -1}, {-2, 4, -1}}. The texture on the polygon is of course not perfectly aligned with the 3D RegionPlot because the 2D plot contains additional margins for the axes and labels. But I'm using what you provided in the question.

Finally, the main point is that in order to combine the two Graphics3D objects p2 and p3, I used the fact that the actual 3D graphics objects are always stored as the first element of the Graphics3D, so one can extract them by doing p2[[1]] and p3[[1]]. The results can then be re-packaged into a new Graphics3D as I do on the last line, adding the lighting and frame options that you chose for p3 in your example.

Note

If you do this kind of combination more frequently, you may also want to look into the closely related answer I posted under “Covering up” text in Graphics where I define a function label3D which can be used to place arbitrary 2D objects into a 3D scene, including transparency effects.

share|improve this answer
    
Hmmm... I updated to 8.0.4 and neither this one or the label3D "Surprise!" example shows up for me. –  JohnD Jul 2 '12 at 2:54
    
Can anyone else reproduce the result above? For me, the bottom graphic appears if and only if Opacity[1]. I'll post the code in the next comment due to space limitations. –  JohnD Jul 2 '12 at 4:37
    
p1 = Plot[x^2, {x, -2, 2}, PlotStyle -> {Thick, Black}]; Manipulate[ Show[Graphics3D[{EdgeForm[], Texture[p1], Polygon[{{-2, 0, -1}, {2, 0, -1}, {2, 4, -1}, {-2, 4, -1}}, VertexTextureCoordinates -> {{0, 0}, {1, 0}, {1, 1}, {0, 1}}], Opacity[w]}, Lighting -> "Neutral", Boxed -> False], RegionPlot3D[-Sqrt[y] <= x <= Sqrt[y] && 0 <= z <= 2 Sqrt[y], {x, -2, 2}, {y, 0, 4}, {z, 0, 4}, Mesh -> False, PlotPoints -> 10, PlotStyle -> Opacity[w], Boxed -> False], BoxRatios -> {1, 1, 1}], {w, 0, 1, .1}] –  JohnD Jul 2 '12 at 4:37
add comment

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.