Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

I have a list of pairs, for example:

pairs={{13, 10}, {12, 14}, {10, 36}, {35, 11}, {3, 5}, {1, 6},
{20, 24}, {21, 22}, {33, 7}, {31, 8}, {31, 27}, {32, 25}, 
{21, 35}, {34, 19}, {18, 15}, {14, 16}, {9, 5}, {4, 7}, 
{1, 13}, {15, 2}, {6, 36}, {4, 34}, {8, 2}, {9, 3}, {25, 20},
{19, 26}, {22, 11}, {23, 12}, {32, 28}, {30, 33}, {23, 16},
{24, 17}, {29, 27}, {26, 30}, {17, 28}, {18, 29}};

pairs can be seen as the definition of a relation $R$. $x$ and $y$ satisfy the relation if and only if {x,y} $\in$ pairs. I need to compute the equivalence classes of the symmetric transitive closure of $R$.

In other words, I need to compute a list eqvclss. The elements of eqvclss are lists themselves. For example, 13, 10, 36, 6, 1, ... should all be in the same list in eqvclss. (If you understand that, then I explained the question properly; if you don't, say so in the comments so I can try to improve).

share|improve this question
    
Related: mathematica.stackexchange.com/q/3234/121 –  Mr.Wizard Jun 29 '12 at 5:29
    
From {13,10} and {10, 36}, you conclude that 10 and 13 belong together. But 13 also belongs with 1 because {1, 13} exists. However, there is no pair {1, 10} or {10, 1}, so 1 shouldn't be in the same group as 10, which is in the same group as 13 which belongs with 1. So the problem for Gather is that your identity relation is not transitive. As a result, you have to give up some conditions. Maybe you want all gathered groups to be numbers that are at least indirectly connected? –  Jens Jun 29 '12 at 5:29
    
@Jens Thanks for your comment. I see now. I did some drastic edits to the question (prior to seeing your comment). Now it's more to the point of what I want. Your comment now seems out of context, but it does answer the original question. –  becko Jun 29 '12 at 5:32
add comment

5 Answers

up vote 8 down vote accepted

Using Daniel Lichtblau's answer to a related question

 ConnectedComponents[Graph[UndirectedEdge @@@ pairs]] //Sort/@#& //Sort

gives

{{3, 5, 9}, 
 {11, 21, 22, 35}, 
 {12, 14, 16, 23}, 
 {1, 6, 10, 13, 36}, 
 {17, 20, 24, 25, 28, 32}, 
 {2, 8, 15, 18, 27, 29, 31}, 
 {4, 7, 19, 26, 30, 33, 34}}

EDIT: An alternative approach:Implementing transitive closure using MatrixPower:

m = Max@pairs;

(*the adjacency matrix of atomic elements in pairs:*)
SparseArray[pairs ~Append~ {i_, i_} -> 1, {m, m}];

(*symmetrize the adjacency matrix:*)
% + %\[Transpose] // Sign;

(*find the transitive closure:*)
Sign @ MatrixPower[N@%, m];

(*eliminate duplicate rows,and extract the atomic elements of pairs in each row:*)
Select[DeleteDuplicates @ Normal @ %, Tr@# > 1 &];
Join @@ Position[#, 1] & /@ %;

(*organize:*)
Sort[Sort /@ %]

Results:

 {{3, 5, 9}, 
  {11, 21, 22, 35},
  {12, 14, 16, 23},
  {1, 6, 10, 13, 36}, 
  {17, 20, 24, 25, 28, 32}, 
  {2, 8, 15, 18, 27, 29, 31}, 
  {4, 7, 19, 26, 30, 33, 34}}
share|improve this answer
    
+1 I think like this better than my answer. –  becko Jun 29 '12 at 5:43
    
@becko, thanks for the vote. (Does the edit answer your request re horizontal scrollbar?) –  kguler Jun 29 '12 at 6:05
    
Yes. The annoying scrollbar is gone. Thanks. –  becko Jun 29 '12 at 6:11
add comment

Here's code for version 7:

Needs["Combinatorica`"]

gr = FromUnorderedPairs @ pairs;

ConnectedComponents @ gr
{{1, 6, 10, 13, 36},
 {2, 8, 15, 18, 27, 29, 31},
 {3, 5, 9},
 {4, 7, 19, 26, 30, 33, 34},
 {11, 21, 22, 35},
 {12, 14, 16, 23},
 {17, 20, 24, 25, 28, 32}}
GraphPlot[gr, VertexLabeling -> True]

Mathematica graphics

share|improve this answer
add comment

Adapting Heike's fine answer from the prior question:

pairs //. x_ :> Union @@@ Gather[x, # ⋂ #2 =!= {} &]
{{1, 6, 10, 13, 36},
 {12, 14, 16, 23},
 {11, 21, 22, 35},
 {3, 5,  9},
 {17, 20, 24, 25, 28, 32},
 {4, 7, 19, 26, 30, 33, 34},
 {2, 8, 15, 18, 27, 29, 31}}
share|improve this answer
    
I had not seen that. I can see is almost the same to what I did. –  becko Jun 29 '12 at 6:01
    
@becko and I did not see your answer before posting this, nevertheless I think it is different enough to be of interest. Do you agree? –  Mr.Wizard Jun 29 '12 at 6:05
    
Yes. Besides, your way is more elegantly coded. –  becko Jun 29 '12 at 6:10
add comment

I have separately posted this method as an answer to this question

If you want to preserve the order in which the vertices are connected within each cycle,

ExtractCycles (in the Combinatorica package) may also be of interest.

For example

Needs["Combinatorica`"]
ExtractCycles@FromUnorderedPairs@pairs

gives

(* { {28, 17, 24, 20, 25, 32, 28},

{23, 12, 14, 16, 23},

{35, 11, 22, 21, 35},

{34, 4, 7, 33, 30, 26, 19, 34},

{9, 3, 5, 9},

{15, 2, 8, 31, 27, 29, 18, 15},

{13, 1, 6, 36, 10, 13} } *)

share|improve this answer
add comment

I just found a way to do it:

SymmetricTransitiveClosure[pairs : {{_, _} ..}] := 
    FixedPoint[DeleteDuplicates /@ 
        Flatten /@ Gather[#, Intersection[#1, #2] =!= {} &] &, pairs]

I won't acccept this yet. Perhaps someone comes up with something better.

share|improve this answer
add comment

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.