How do you change the font size of a Manipulator label?

Question

I have a stand alone Manipulator (it is not in a Manipulate) and would like to know how to alter the style of the label. There are no explicit styling options for Manipulator so I tried wrapping it in Style:

Style[
 Manipulator[0.5, AppearanceElements -> None,
  Appearance -> {"Labeled"}, ImageSize -> Small],
 FontSize -> 20]

this didn't work.

I have also noticed that I cannot set an image size other than a named size. In other words ImageSize does not accept a number!

Manipulator[0.5, AppearanceElements -> None,
  Appearance -> {"Labeled"}, ImageSize -> 100]

and

Manipulator[0.5, AppearanceElements -> None,
  Appearance -> {"Labeled"}, ImageSize -> 400]

produce the same output. Are these issues possible bugs or am I overlooking something?

Q1. How can I change the font size (and other font styling but mainly font size) for the Manipulator label?

Q2. How can I make ImageSize accept a number rather than a name?

Edit

My question is not about what alternatives exist to using Manipulator. I have posted an example with AppearanceElements -> None so as to make the label the sole focus. However I want the possibility of being able to add back in the AppearanceElements is desired/required. The setting AppearanceElements -> None obviously looks like a stand alone slider and has led to readers thinking in terms of sliders rather than "fixing" the Manipulator.

Edit #2

In situations when no Manipulator controls are wanted Slider is an alternative but it also has some strange behaviour:

Framed@Slider[Dynamic[x], Appearance -> "Labeled", BaseStyle -> FontSize -> 20, ImageSize -> 100]
Framed@Slider[Dynamic[x], Appearance -> "Labeled", BaseStyle -> FontSize -> 20, ImageSize -> 200]

So it appears that the label occupies the same image size as the slider! This presents a problem in a GUI layout but there is a work around:

Framed@Pane[Slider[Dynamic[x], Appearance -> "Labeled", 
BaseStyle -> FontSize -> 20, ImageSize -> 200], ImageSize -> 260]

But the image space allocated to the label looks like a bug or something unintended. This doesn't address my question but I add it here because slider answered have been given.

FWIW:

Edit #3

Tech support confirm that the strange image sizing for Slider when a label is used is a bug.

Answer 1

I suppose you could roll your own, as in

s = 0.5;
Row[{Manipulator[Dynamic[s]], " ", 
  Style[Dynamic[s], FontSize -> 16]}]

Answer 2

To add to the spectrum of solutions here I suggest these approaches.

1) ----------- Magnify -----------

Magnify will uniformly change the size of Manipulator, its numeric label and everything that is related to that. It will work inside an interface too:

Manipulate[

 DynamicModule[{f = 1}, 
  Column@{Magnify[
     Manipulator[Dynamic[f], {0.25, 5}, AppearanceElements -> None, 
      Appearance -> "Labeled"], x], 
    Dynamic[Plot[Sin[f x], {x, -2 \[Pi], 2 \[Pi]}, ImageSize -> 500]]}]

 , {{x, 1, "Magnification of Manipulator"}, .5, 2, 
  Appearance -> "Labeled"}]

Disadvantage of course is that you cannot change the size of individual elements separately.

2) ----------- Ctrl+Shift+E -----------

I figured it out only for the Manipulator ImageSize, not the label. Maybe it is possible for label too. When you get you Manipulator select its cell, press CTRL+SHIFT+E, put numeric size as shown below, press CTRL+SHIFT+E again.

Answer 3

Based on the code digging by @kguler the internal code controlling this is:

FEPrivate`If[#9, {InputFieldBox[#1, Expression, 
   FieldSize -> {{4, 10}, {1, 2}}, Enabled -> #6, 
   Appearance -> {"Frameless", #8}, BaseStyle -> "Manipulator"]}, {}]

so it looks like you can change some of this via a style sheet -- for a notebook wide solution:

Cell[StyleData["Manipulator"],
 FontSize->18,
 Background->RGBColor[1,1,0]]

This still has its obvious limitations: it is notebook wide not local, (and if you wanted to adjust FieldSize to you can't), and the image size problem can't be solved by this approach. I don't regard this as a complete answer to the question but may be of interest.

Edit

Tech support confirm what can be inferred from the code that @kguler found -- namely that the label styling and numerical image size can not be set by the user programmatically.

To alter the label you have to use a stylesheet as per this answer. To alter the image size you would have to do that by changing the underlying expression in the output cell as per @Vitaliy's answer.

Answer 4

Use Slider in which case you can use numerical values for ImageSize.

Row[{Slider[Dynamic[n], {0, 100, 1}, ImageSize -> {150, 50}, 
   ImageMargins -> 10], Style[Dynamic[n], FontSize -> 16]}]

Answer 5

A Slider seems to have the options you want

Slider[0.5, Appearance -> "Labeled", BaseStyle -> FontSize -> 20, ImageSize -> 100]

I'm not sure of the differences between a Slider and a Manipulator