Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

How do I control the shape of my arrow heads? LaTeX's TikZ package has a wide variety of predefined arrowhead styles, some of which I'd like to try to match for Mathematica figures I'm importing into a LaTeX document:

LaTeX arrow examples

But Mathematica's default arrowhead style comes nowhere near any of these. For example,

Graphics[{Thick, Arrow[{{0, 0}, {-50, 0}}]}] 

yields

Default Mathematica arrow

Earlier versions of Mathematica had options for controlling arrowhead shape, but those seem to be gone in 8.0.

How can I get the shape of my Mathematica arrowheads to match the LaTeX TikZ arrowhead styles?

share|improve this question
    
In addition, Mathematica's arrows are scaled differently from LaTeX arrowheads, using a logic I can't discern. Ideally I'd like to also ensure that my Mathematica arrows scale the same way LaTeX arrows do; but that is perhaps a separate question. –  raxacoricofallapatorius Jun 19 '12 at 17:39
    
Have you looked at the documentation of Arrowheads? –  Heike Jun 19 '12 at 17:42
    
Yes, naturally. Nothing there got me close. –  raxacoricofallapatorius Jun 19 '12 at 17:43
2  
@Heike: that only gives one example for a custom arrowhead, but nothing about predefined types (though StreamPlot has a miriad of different built-in arrow styles). –  István Zachar Jun 19 '12 at 17:44
2  
See this question -- it will show how to define custom shapes, and set absolute arrowhead sizes. –  Mr.Wizard Jun 19 '12 at 17:58

2 Answers 2

up vote 20 down vote accepted

Here is a Manipulate to design yourself an Arrow:

DynamicModule[{top, baseMid, rightBase, outerMidRight, innerMidRight},
 Manipulate[
  top = {0, 0};
  baseMid = {1, 0} baseMid;
  rightBase = {1, -1} leftBase;
  outerMidRight = {1, -1} outerMidLeft;
  innerMidRight = {1, -1} innerMidLeft;
  h = Graphics[
    {
     Opacity[0.5],
     FilledCurve[
      {
       BSplineCurve[{baseMid, innerMidLeft, leftBase}],
       BSplineCurve[{leftBase, outerMidLeft, top}],
       BSplineCurve[{top, outerMidRight, rightBase}],
       BSplineCurve[{rightBase, innerMidRight, baseMid}]
       }
      ]
     }
    ],
  {{baseMid, {-2, 0}}, Locator},
  {{innerMidLeft, {-2, 0.5}}, Locator},
  {{leftBase, {-2, 1}}, Locator},
  {{outerMidLeft, {-1, 1}}, Locator}
  ]
 ]

Mathematica graphics

It is easy to add more control points if the need arises.

The arrowhead graphics is put in the variable h. Note that it contains an Opacity function for better visibility of the control points. You need to remove that if you want to have a fully saturated arrow head.

Some examples generated with this Manipulate using:

Graphics[
  { Arrowheads[{{Automatic, 1, h /. Opacity[_] :> Sequence[]}}],
    Arrow /@ 
        Table[{{0, 0}, {Sin[t], Cos[t]}}, {t, 0, 2 \[Pi] - 2 \[Pi]/20, 2 \[Pi]/20}]
  }, 
     PlotRangePadding -> 0.2
 ]

Mathematica graphics

The code for the arrow heads can be found in h. Just copy the graphics or the FullForm to store it for later use.

h /. Opacity[_] :> Sequence[] // FullForm

(* ==>
Graphics[{FilledCurve[{BSplineCurve[{{-0.496, 0.}, {-1., 0.48}, {-2,1}}],            
    BSplineCurve[{{-2, 1}, {-0.548, 0.44999999999999996}, {0, 0}}], 
    BSplineCurve[{{0, 0}, {-0.548, -0.44999999999999996}, {-2, -1}}], 
          BSplineCurve[{{-2, -1}, {-1., -0.48}, {-0.496, 0.}}]}]}
]
*)

EDIT
One more control point will cover most common shapes:

DynamicModule[{top, baseMid, outerMidRight, innerMidRight, 
  innerBaseRight, outerBaseRight},
 Manipulate[
  top = {0, 0};
  baseMid = {1, 0} baseMid;
  innerBaseRight = {1, -1} innerBaseLeft;
  outerBaseRight = {1, -1} outerBaseLeft;
  outerMidRight = {1, -1} outerMidLeft;
  innerMidRight = {1, -1} innerMidLeft;
  h = Graphics[
    {
     Opacity[0.5],
     FilledCurve[
      {
       BSplineCurve[{baseMid, innerMidLeft, innerBaseLeft}],
       Line[{innerBaseLeft, outerBaseLeft}],
       BSplineCurve[{outerBaseLeft, outerMidLeft, top}],
       BSplineCurve[{top, outerMidRight, outerBaseRight}],
       Line[{outerBaseRight, innerBaseRight}],
       BSplineCurve[{innerBaseRight, innerMidRight, baseMid}]
       }
      ]
     }
    ],
  {{baseMid, {-2, 0}}, Locator},
  {{innerMidLeft, {-2, 0.5}}, Locator},
  {{innerBaseLeft, {-2, 1}}, Locator},
  {{outerBaseLeft, {-2, 1.1}}, Locator},
  {{outerMidLeft, {-1, 1}}, Locator}
  ]
 ]

Mathematica graphics

Mathematica graphics

share|improve this answer
6  
+1 This should be part of Mathematica 9. –  István Zachar Jun 20 '12 at 10:59
    
Amazing! Thanks! –  raxacoricofallapatorius Jun 20 '12 at 16:13

One source of arrowhead shapes is Graph which comes with a list of predefined arrowhead shapes that you can set using the option EdgeShapeFunction. You can get the names of these shapes by doing something like

arrowheadNames = GraphElementData["Edge"];

Unfortunately, these names by themselves are useless in Arrowheads. Luckily there is a way to extract the Graphics specifications of these arrowheads by converting a Graph to Graphics using Show and extracting the Arrowheads directives:

headlist = 
  Flatten[Cases[
      Show[Graph[{1 \[DirectedEdge] 2}, EdgeShapeFunction -> #]], 
      Arrowheads[a_] :> 
       Cases[a, b_GraphicsBox :> ToExpression[b], Infinity, 1], 
      Infinity, 1] & /@ arrowheadNames];

GraphicsGrid[Partition[headlist, 5, 5, {1, 1}, ""], Frame -> All]

Mathematica graphics

You can use these in Arrowheads as follows:

grlist = Graphics[{Arrowheads[{{.3, 1, #}}], Arrow[{{0, 0}, {1, 1}}]}] & /@ headList;

GraphicsGrid[Partition[grlist, 5, 5, {1, 1}, ""], Frame -> All]

Mathematica graphics

share|improve this answer

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.