How to extract and compute on the diagonal entities of a sparse matrix very fast?

Question

As could be seen in the following code:

AbsoluteTiming[
    n  = 100000;
    A  = SparseArray[{
         Band[{1, 120}] -> -2., Band[{950, 1}] -> -1., 
         Band[{1, 1}] -> 20., Band[{1, 100}] -> 2., 
         Band[{6, 800}] -> 1.1}, {n, n}, 0.];
    b  = SparseArray[Table[1., {i, n}]];
    DA = Diagonal[A];

    (* I think constructing B is time-consuming. My ParallelTable[] does 
    not work or show any improvement herein! *)

    B = SparseArray[Table[(1/DA[[i]]), {i, 1, n}]];
    V = DiagonalMatrix[SparseArray[B]];
]

I'm trying to extract the diagonal entries of a very large sparse matrix and to compute $1/a_{ii}$ to make my new large sparse diagonal matrix $V$. This process takes around 18 seconds, and I would like to accelerate this process.

Answer 1

You can create your new diagonal matrix V in a single step as:

V = DiagonalMatrix@SparseArray[1/Normal[Diagonal[A]]];

On my machine, this takes 0.05 seconds, compared to 9 seconds for your code above (excluding time taken to construct A).

You can verify that they're both the same:

DiagonalMatrix[SparseArray[B]] == DiagonalMatrix@SparseArray[1/Normal[Diagonal[A]]]
(* True *)

Answer 2

I'm probably missing something important here, but it seems to me that one does not have convert back and forth to Normal form, meaning that DiagonalMatrix[ 1/Diagonal[A] ] works:

DiagonalMatrix[ 1/Diagonal[A] ] == DiagonalMatrix[ SparseArray[B] ]

(* True *)