Plot3D in Mathematica: how to plot in presence of parameters

Question

I do thank you Vitaly and Celtschk.

I should have disclosed my ultimate goal earlier so as to receive the best help.While the previous suggestions were very helpful, I think I realize I ill-posed the question earlier

I am trying to find the values of A and B that will maximize function f on the domain {x,0,100},{y,0,100}. I have had trouble using Maximize or NMaximize, etc. So I am trying to find x and y in terms of A and B, which will maximize the function.

this function f has two parameters A and B in it with constraints such that $ 0< A < 100 $ and $A < B \le 100$.

My actual function is: Mathematica Input:

---

(B^3 - B^2 (x + y) + x (A^2 - y^2 + A (-x + y)) + B (x^2 + x y + y^2 - A (x + y)))/(A - B)^2

---

$$ (B^3 - B^2 (x + y) + x (A^2 - y^2 + A (-x + y)) + B (x^2 + x y + y^2 - A (x + y)))/(A - B)^2\bigl) $$

Answer 1

Use Manipulate function to interactively change the parameters values. The If statement is to auto-remove breaking of controls due to getting out of proper range.

Manipulate[
 If[B < A, B = A];
 Plot3D[A^3 - A^2 (x + y) + x (B^2 - y^2 + B (-x + y)), {x, 0, 
   100}, {y, 0, 100}, PlotStyle -> Opacity[.7], 
  ColorFunction -> "Rainbow"], {{A, 50}, 0, 99.9, 
  Appearance -> "Labeled"}, {{B, 100}, A, 100, 
  Appearance -> "Labeled"}, FrameMargins -> 0]

Answer 2

Parameters should have numerical values. Otherwise it is done by a standard command Plot3D:

A = 10; B = 20;
Plot3D[(A^3 - A^2 (x + y) + x (B^2 - y^2 + B (-x + y))), {x, -100, 
  100}, {y, -100, 100}, PlotRange -> All]

If the question is about how to change parameters interactively and see that happens it can be done with Manipulate.

Answer 3

Besides interactive manipulation, you might also just want to see a set of surfaces with different parameter settings in a single picture:

Plot3D[Evaluate@Table[Tooltip[A^3-A^2 (x+y)+x(B^2-y^2+B(-x+y)),
                              Style["A = " <> ToString[A]
                                    <> ", B = "<>ToString[B],
                                    Background->White]],
                      {A, 1, 100, 33}, {B, A, 100, 33}],
       {x, 0, 100}, {y, 0, 100},
       PlotStyle -> {Green, Darker[Yellow], Red, Blue, Cyan, Magenta,
                     Brown, Orange, Purple, Pink}]