Splitting a list

Question

Please consider the following list:

data={1, 0, 0, 0, 2, 5, 2, 3, 0, 0, 3};

Now I would like to split the list into 0-sequences and Not-0-sequences as following:

{{1}, {0, 0, 0}, {2, 5, 2, 3}, {0, 0}, {3}}

All numbers are non-negative Integers, if that helps.

Answer 1

Split[{1, 0, 0, 0, 2, 5, 2, 3, 0, 0, 3}, Xor[#1 != 0, #2 == 0] &]

or more compactly

Split[{1, 0, 0, 0, 2, 5, 2, 3, 0, 0, 3}, Xnor[#1 == 0, #2 == 0] &]

works nicely here. Another way is:

SplitBy[{1, 0, 0, 0, 2, 5, 2, 3, 0, 0, 3}, Unitize]

or

SplitBy[{1, 0, 0, 0, 2, 5, 2, 3, 0, 0, 3}, Sign]

or, as Szabolcs suggests:

SplitBy[{1, 0, 0, 0, 2, 5, 2, 3, 0, 0, 3}, # == 0 &]

Answer 2

I recently read The Little Schemer by Friedman and Felleisen, so the following construction suggests itself:

split[{}]={};
split[{Longest[x__?(#>0&)] | Longest[x__?(#==0&)], y___}]:=Join[{{x}},split[{y}]];

In[34]:= split[{1,0,0,0,2,5,2,3,0,0,3}]
Out[34]= {{1},{0,0,0},{2,5,2,3},{0,0},{3}}

I make no claim that this is at all practical.

Answer 3

Here's a recursive rule based solution for fun:

Clear[f]
f[l_List] := l /. {x__?(# != 0 &) | Longest[x : 0 ..], y___} :> {{x}, Sequence @@ f[{y}]}
f[{x_}] := {{x}}

f[{1, 0, 0, 0, 2, 5, 2, 3, 0, 0, 3}]    
(* {{1}, {0, 0, 0}, {2, 5, 2, 3}, {0, 0}, {3}} *)

Answer 4

This isn't going to win any awards for efficiency but I had fun putting it together.

f[{h_, t__}] := f[{h}, {t}]

f[x___, {a_, b___}, {h_, t__}] := 
  If[
     (h == 0) == (a == 0),
     f[x, {a, b, h}, {t}],
     f[x, {a, b}, {h}, {t}]
  ]

f[x___, y : {_}] := {x, y}

f @ {1, 0, 0, 0, 2, 5, 2, 3, 0, 0, 3}

{{1}, {0, 0, 0}, {2, 5, 2, 3}, {0, 0}, {3}}