Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

I tried to avoid using the subscript $A_0$ in the Module, and get an error with $A[0]$.

    In[119]:= Module[{A[0] = 1},A[0]]

         During evaluation of In[119]:= Module::lvset: Local variable specification {A[0]=1} contains A[0]=1, which is an assignment to A[0]; only assignments to symbols are allowed. >>

      Out[119]= Module[{A[0] = 1}, A[0]]

EDIT:

Alternatively, I tried to define "A0, A1, A2", but failed with command

         Sum[Ai, {i, 3}]

I just want a Symbol of combining a letter with a postfix of number, e.g. Ai, A_i, A[i], A(i),... any notation that is treated as a Symbol in MMa would be okay.

EDIT2:

For example,

    In[130]:= Module[{A0 = 1},Sum[Symbol["A" <> ToString[i]], {i, 0, 3}]]

     Out[130]= A0 + A1 + A2 + A3

But I wish to replace $A0$ with $1$, and get 1+ A1 + A2 + A3

This would work when A0 defined globally.

     In[132]:= Sum[Symbol["A" <> ToString[i]], {i, A0 = 1; 0, 3}]

     Out[132]= 1 + A1 + A2 + A3
share|improve this question
    
What about using the Notation package, in particular, Symbolize? –  Simon Jun 10 '12 at 6:29
add comment

2 Answers

up vote 10 down vote accepted

Honestly I would suggest to not create symbols with Symbol or ToExpression for that use case. You can very well use Downvalues as you tried in the first place also for local variables, you just can't make those definitions within the local symbols list, e.g. this will work:

Module[{A},A[0] = 1; Sum[A[i],{i,0,3}]]

As explained in answers to other questions (e.g. here) localication with Module will actually create a "new" symbol (something like A$573) which will in this case leak from the Module (this is called lexical scoping, at least in Mathematica speak. It can be argued whether what Module does actually qualifies for what that term is used in general). These leaking symbols can be used as a feature, but I doubt it is what you want in this case.

The following might be closer to what you actually had in mind, although it also can have subtleties when used in more complicated circumstances (see again e.g. here for more details and links):

Block[{A}, A[0] = 1; Sum[A[i],{i,0,3}]]

There is also Array which I think should be mentioned in that context:

Module[{A}, A[0] = 1; Total@Array[A, 4, 0]]
share|improve this answer
    
With In[207]:= Module[{A}, A[0] = 1; Sum[A[i], {i, 0, 3}]], I got this ` Out[207]= 1 + A\$2471[1] + A\$2471[2] + A\$2471[3]`. Is this normal? How to remove "\$2471" here? –  Osiris Xu Jun 12 '12 at 0:33
    
@OsirisXu: yes, that is the expected behaviour. As I mentioned, typically the Block construct seems more appropriate in this context, but it all depends. What you see with Module is the local variables leaking. You'll find quite some answers on this site where this is explained and where this is used as a feature (search for Module,scoping,local variables). –  Albert Retey Jun 12 '12 at 8:55
    
Nice. Thank you. –  Osiris Xu Jun 12 '12 at 20:25
add comment

One option is to assemble symbols as strings and use Symbol:

Sum[
  Symbol["x" <> ToString[i]],
  {i, 5}
]
x1 + x2 + x3 + x4 + x5

For use in Module you will need to inject this symbol, e.g. using With:

With[{sym = Symbol["x" <> ToString[3]]},
  Module[{sym = 7}, sym + 3]
]
10

Also be aware of Unique and its function:

Unique["x"]
x6

Judging from your second example Module may be the wrong tool for the job. Consider:

Block[{A0 = 1}, Sum[Symbol["A" <> ToString[i]], {i, 0, 3}]]

Sum[Symbol["A" <> ToString[i]], {i, 0, 3}] /. A0 -> 1

Sum[a[i], {i, 0, 3}] /. a[0] -> 1
1 + A1 + A2 + A3

1 + A1 + A2 + A3

1 + a[1] + a[2] + a[3]
share|improve this answer
    
This is nice. But this notation is not that convenient to use. Any other alternatives? I just want a Symbol of combining a letter with a postfix of number, e.g. Ai, A_i, A[i], A(i),... any notation that is treated as a Symbol in MMa would be okay. –  Osiris Xu Jun 10 '12 at 0:40
    
@OsirisXu could you give an example application for this? That will help me determine methods that may be applicable. –  Mr.Wizard Jun 10 '12 at 0:42
    
For example, In[130]:= Module[{A0 = 1},Sum[Symbol["A" <> ToString[i]], {i, 0, 3}]] Out[130]= A0 + A1 + A2 + A3 But I wish to replace $A0$ with $1$, and get 1+ A1 + A2 + A3 –  Osiris Xu Jun 10 '12 at 0:45
    
@OsirisXu I need more context than that. What operation or procedure are you doing? For that example would Sum[A[i], {i, 0, 3}] /. A[0] -> 1 be acceptable? –  Mr.Wizard Jun 10 '12 at 0:49
4  
In other words, @Osiris, what are you really trying to do? –  J. M. Jun 10 '12 at 0:51
show 2 more comments

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.