How to expand all portions of an expression?

Question

Consider a toy expression:

expr = Sin[x (a + b)]/(y (z + c))

I would like to expand all parentheses to get something like:

Sin[a x + b x]/(c y + y z)

I have been able to expand the argument of the Sin term using:

MapAll[Expand,expr]
(* Out[] = Sin[a x + b x]/(y (c + z)) *)

However, this leaves the denominator unexpanded. Is there a way to expand the entire expression?

Answer 1

I just found the ExpandDenominator function which, as the name implies, expands the denominator of the expression. Then, Expand and ExpandDenominator can be cobbled together using:

ExpandDenominator //@ Expand //@ expr

(Thanks Mr. Wizard for the improved cleanliness.) However, there is also a related built-in function that does this all in one shot:

ExpandAll[expr]
(* Out[] = Sin[a x + b x]/(c y + y z) *)

Answer 2

It seems that an expression like 1/((a + b) x) is totally deceiving. It doesn't remain unevaluated, it evaluates to something, but that other something is formatted in the same way as the original.

1/((a + b) x) // FullForm // HoldForm

Times[1, Power[Times[Plus[a, b], x], -1]]

1/((a + b) x) // FullForm

Times[Power[Plus[a, b], -1], Power[x, -1]]

So, as you can see, it evaluates to something that should look like 1/(a+b) 1/x That's why Expand never gets mapped to a polynomial denominator.

Try, for example

Expand//@Unevaluated[Sin[x (a + b)]/(y (z + c))]

Sin[a x + b x]/(c y + y z)