Efficient setting of properties of multiple vertices in Graph

Question

The functions SetProperty and PropertyValue can only set a single property of a single vertex, as far as I know. How do I set a property for multiple vertices simultaneously?

In the documentation, they recommend using Do to set multiple properties, but I've heard that Do is not the most efficient way to do things in Mathematica. Are there any alternatives?

EDIT : The only approach seems to make several calls to SetProperty or PropertyValue (which is faster), one call for each distinct vertex property I want to set. From the answers so far it seems that there is no Mathematica equivalent to SetProperty or PropertyValue that sets several properties of distinct vertices at once. But I'd still hope that something could be done directly on the Graph object, bypassing SetProperty and PropertyValue.

Answer 1

It may be not clear from documentation but SetProperty and PropertyValue can take "global to graph" specifications to apply simultaneously to all objects

Row@{g = CompleteGraph[4, PlotRangePadding -> .2], 
  PropertyValue[g, VertexLabels] = "Name"; g}

and even sets of "global to graph" specifications put in a list:

Row@{g = CompleteGraph[12, PlotRangePadding -> .3, ImageSize -> 300], 
  SetProperty[
   g, {VertexSize -> .4, VertexLabels -> "Name", 
    VertexStyle -> Directive[Opacity[.4], Green], 
    EdgeStyle -> Directive[Thickness[.02], Opacity[.2], Red]}]}

Also, if you have unique-to-object options you can specify them by other than Do means. The documentation has examples of functional programming. For instance, slightly modifying this example using Fold:

Row@{g = CompleteGraph[8, VertexSize -> Large],
  Fold[SetProperty[{#1, #2}, VertexStyle -> ColorData[45, #2]] &, g, Range[1, 8]]}

Or this example with Do that you've seen, can be done with Map:

Row@{g = CompleteGraph[15, VertexSize ->Large], 
    (PropertyValue[{g, #[[1]]}, VertexStyle] = #[[2]]) & /@ 
     Transpose[{Range[15], ColorData[1, "ColorList"]}]; g}

Answer 2

I don't think you will get much better performance using functional approaches here, since the call to SetProperty is the bottleneck instead of the Do loop. Anyway it says in the documentation that PropertyValue is much faster than SetProperty. We can check both assumptions:

g = CycleGraph[1000];
Timing@Do[
  PropertyValue[{g, v}, VertexWeight] = RandomReal[], {v, 
   VertexList[g]}]

(* ==> {0.016, Null} *)

g = CycleGraph[1000];
Timing@Do[
  SetProperty[{g, v}, VertexWeight -> RandomReal[]], {v, 
   VertexList[g]}]

(* ==> {2.25, Null} *)

(*Try scan*)
g = CycleGraph[1000];
Timing@Scan[(PropertyValue[{g, #}, VertexWeight] = RandomReal[]) &, 
  VertexList[g]]

(* ==> {0.031, Null} *)

g = CycleGraph[1000];
Timing@Scan[(SetProperty[{g, #}, VertexWeight -> RandomReal[]]) &, 
  VertexList[g]]

(* ==> {2.625, Null} *)

From this we see that for this example PropertyValue is indeed much better and that using Scan has no benefits.