Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

I wish to create a nice data representation of three nested spherical sections, with a cut away so they can be viewed. As a MWE, something like;

a = SphericalPlot3D[{1}, {\[Theta], 0, Pi}, {\[Phi], 0, 4 Pi/2}, 
   PlotStyle -> Directive[Blue, Opacity[0.7], Specularity[White, 20]],
    Mesh -> None, PlotPoints -> 40];

b = SphericalPlot3D[{2}, {\[Theta], 0, Pi}, {\[Phi], 0, 3 Pi/2}, 
   PlotStyle -> Directive[Red, Opacity[0.7], Specularity[White, 20]], 
  Mesh -> {{0}, {0}, {0}}, PlotPoints -> 40];

c = SphericalPlot3D[{3}, {\[Theta], 0, Pi}, {\[Phi], 0, 3 Pi/2}, 
   PlotStyle -> 
   Directive[Green, Opacity[0.7], Specularity[White, 20]], 
  Mesh -> {{0}, {0}, {0}}, PlotPoints -> 40];

abc = Show[a, b, c, PlotRange -> Automatic]

This gives me the following image, after some rotation for clarity;

Nested spheres

This is kind of the idea, but the problem is that this displays as spherical surfaces at r = 1, r = 2 and r = 3. In reality, there is a thick spherical shell (let's say a red one) for $1 \leq r \leq 2$ and a thick spherical shell (a green one) at $2 \leq r \leq 3$. The spherical core at $r \leq 1$ is solid blue. Is there a nice way to make this image? I was hoping I could somehow modify the $r$ term in the SphericalPlot3D function to do this.

I could also like to add a vertical line running through the sphere centre (z = 0) to make the image clearer. Any ideas?

Thanks

share|improve this question

marked as duplicate by Öskå, Pickett, Mr.Wizard Aug 15 at 14:55

This question has been asked before and already has an answer. If those answers do not fully address your question, please ask a new question.

    
Why not try using Plot3D and Filling –  Jagra Aug 15 at 13:16
    
Im not sure how to go about this, as AFAIR Plot3D only takes functions of 2 variables ? I suppose I could rewrite equation of sphere but seems messy.. –  DRG Aug 15 at 13:38
    
Related: (41985) –  Pickett Aug 15 at 14:14
    
Related: (14954) –  Mr.Wizard Aug 15 at 14:56

2 Answers 2

up vote 5 down vote accepted
SetOptions[{SphericalPlot3D, ParametricPlot3D}, Mesh -> None];

fun = {r {0, -Sin[t], Cos[t]}, r {Sin[t], 0, Cos[t]}};

p1 = SphericalPlot3D[{2, 2.5},
   {u, 0, Pi}, {v, 0, 1.5 Pi},
   PlotStyle -> Directive[Green, Opacity[0.7], Specularity[White, 20]]];

p2 = ParametricPlot3D[fun,
   {r, 2, 2.5}, {t, 0, Pi},
   PlotStyle -> Directive[Green, Opacity[0.7], Specularity[White, 20]]];

p3 = SphericalPlot3D[{1.5, 1.99},
   {u, 0, Pi}, {v, 0, 1.5 Pi},
   PlotStyle -> Directive[Red, Opacity[0.7], Specularity[White, 20]]];

p4 = ParametricPlot3D[fun,
   {r, 1.5, 1.99}, {t, 0, Pi},
   PlotStyle -> Directive[Red, Opacity[0.7], Specularity[White, 20]]];

p5 = SphericalPlot3D[{1, 1.48},
   {u, 0, Pi}, {v, 0, 2 Pi},
   PlotStyle -> Directive[Blue, Opacity[0.7], Specularity[White, 20]]];

Show[p1, p2, p3, p4, p5, PlotRange -> All]

enter image description here

Show[p1, p2, p3, p4, p5, PlotRange -> All, ViewPoint -> Front]

enter image description here

Edit

With the new V10 function ClipPlanes you can easily slice your graphics:

Grid[
 {{
   Show[p1, p2, p3, p4, p5, ClipPlanes -> {{-1, 1, 0, 1}}, ImageSize -> 400],
   Show[p1, p2, p3, p4, p5, ClipPlanes -> {{0, 0, -1, 0}}, ImageSize -> 400]
   }}]

enter image description here

share|improve this answer
    
Thanks ! This worked a treat! –  DRG Aug 15 at 16:24
    
@DRG Thanks for acceptance, interesting question :) –  eldo Aug 15 at 18:07
    
Nice use of ClipPlanes! –  chris Aug 16 at 13:55
regionsandcolors =  Thread[
   {{(x <= 0 || y >= 0) && x^2 + y^2 + z^2 < 1,
     (x <= 0 || y >= 0) &&  1 <= x^2 + y^2 + z^2 < 2,
     (x <= 0 || y >= 0) &&  2 <= x^2 + y^2 + z^2 <= 3}, {Blue, Red, Green}}]; 
plots =  RegionPlot3D[#1, {x, -3, 3}, {y, -3, 3}, {z, -3, 3}, Mesh -> None, 
       PlotStyle -> FaceForm[{Opacity[.9], #2}], 
       PlotRange -> {{-3, 3}, {-3, 3}, {-3, 3}}, PlotPoints -> 100, 
       MaxRecursion -> 10] & @@@ regionsandcolors;
Show[plots]

enter image description here

share|improve this answer
    
This really had me puzzled. So many simple ways that Mathematica ought to let one do this but doesn't ;-( Great solution with broad application. +1 –  Jagra Aug 15 at 13:55
    
@Jagra, thank you for the upvote. I agree, this seems to fall in the cracks between Mathematica's many xPlot3D functions:) –  kguler Aug 15 at 14:11
    
Very clever - I like this approach too. Thanks so much! –  DRG Aug 15 at 16:24

Not the answer you're looking for? Browse other questions tagged or ask your own question.