Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

How can I obtain a non-trivial solution of the following:

$$\frac{a}{b+c}=\frac{b}{c+a}=\frac{c}{a+b}$$

The answer is $a=b=c=1$.

share|improve this question
1  
Are you sure that this is about the software Mathematica? –  Öskå Aug 14 at 10:12
    
Why $a=b=c=\frac{1}{2}$ is better than e.g. $a=b=c=1$ or just $a=b=c=d$ for any complex $d$??? –  Artes Aug 14 at 10:14
    
yes, how to program this in mathematica such that it gives the answer given. Otherwise it is giving trivial solution a = b = c = 0, but i dont know how to program for non-trivial... –  xclassmechluv Aug 14 at 10:14
    
@Artes good catch. i m sorry –  xclassmechluv Aug 14 at 10:16
1  
Try e.g. FindInstance[ a/(b + c) == b/(c + a) == c/(a + b), {a, b, c}, Rationals, 5], there are infinitely many solutions. –  Artes Aug 14 at 10:22

3 Answers 3

up vote 3 down vote accepted

Perhaps what you looking for is Reduce. It will give the whole solution space of your equations.

Reduce[a/(b + c) == b/(a + c) == c/(a + b), {a, b, c}, Reals]

reduce

This should make it clear that a == b == c == 1 is not the answer.

At the request of the OP in a comment below, here is a non-trivial solution where the three variables are not equal.

ratios = a/(b + c) == b/(a + c) == c/(a + b);
ratios /. {a -> 1, b -> -5, c -> 4}
True

The values for a, b, and c come from solution sub-space

 a > 0 && b < -a && c == (-a^2 + b^2)/(a - b)

which can be read off from the result returned by Reduce.

share|improve this answer
    
I'm curious why a == b == c == 1 is not answer??? –  Artes Aug 14 at 10:37
3  
@Artes. Of course it's an answer. "... not the answer" is an English idiom for "not the only answer". It is a short form of "it's an answer, but not the answer". –  m_goldberg Aug 14 at 10:41
    
@m_goldberg please suggest other answers –  xclassmechluv Aug 14 at 10:56
    
can anybody graphically present the solution set? –  xclassmechluv Aug 14 at 12:52
1  
@xclassmechluv. Please stop asking extensions to your question in comments. Either formulate a new question referring to this one, or edit your question so it includes the extensions. You chances for getting the additional information you seek will be much better. –  m_goldberg Aug 14 at 12:56

As there are infinite solutions you must limit the scope of your search. You can find your desired a == b == c ==1 with f.e.:

 FindInstance[
     a/(b + c) == b/(c + a) == c/(a + b) && 
        0 < a < 10 && 0 < b < 10 && 0 < c < 10, 
           {a, b, c}, Integers, 9]

{{a -> 1, b -> 1, c -> 1}, {a -> 2, b -> 2, c -> 2}, {a -> 3, b -> 3, c -> 3}, {a -> 4, b -> 4, c -> 4}, {a -> 5, b -> 5, c -> 5}, {a -> 6, b -> 6, c -> 6}, {a -> 7, b -> 7, c -> 7}, {a -> 8, b -> 8, c -> 8}, {a -> 9, b -> 9, c -> 9}}

Solve[a/(b + c) == b/(c + a) == c/(a + b) && 
   0 < a < 10 && 0 < b < 10 && 0 < c < 10, {a, b, c}, Integers]

Same output as above

Reduce[a/(b + c) == b/(c + a) == c/(a + b) && 
   0 < a < 10 && 0 < b < 10 && 0 < c < 10, {a, b, c}]

0 < a < 10 && b == a && c == b

share|improve this answer

Mathematica can solve this problem completely. It provides three types of non-trivial solutions.

Here we go

The two defining eqations are

eq1 = a/(b + c) == b/(c + a);

eq2 = b/(c + a) == c/(a + b);

Solving these, one by one, using Solve without specifying the variables to solve for

Solve [eq1]
{{a -> b}, {a -> -b - c}}
Solve [eq2]
{{a -> -b - c}, {b -> c}}

Solving both simultaneously, as required, gives

sol = Solve[eq1 && eq2]
{{a -> -b - c}, {a -> -(c/2), b -> -(c/2)}, {a -> c, b -> c}, {b -> -(a/2), 
  c -> -(a/2)}}

Check the solutions

eq1 /. sol // Simplify
{True, True, True, True}
eq2 /. sol // Simplify
{True, True, True, True}
eq1 && eq2 /. sol // Simplify
{True, True, True, True}

Now let' s look at the solutions one by one

{a, b, c} /. sol[[1]]
{-b - c, b, c}
{a, b, c} /. sol[[2]]
{-(c/2), -(c/2), c}
{a, b, c} /. sol[[3]]
{c, c, c}
{a, b, c} /. sol[[4]]
{a, -(a/2), -(a/2)}

We see that the first three solutions are structurally different from each other, the fourth is similar to solution 2.

Best regards, Wolfgang

share|improve this answer
    
@ Öskå: Thanks for the editing. How did you treat the Out-parts (now in a separate Grey field indented a bit more than the command, and a thin read vertical line)? –  Dr. Wolfgang Hintze Aug 14 at 21:56

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.