Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

I integrated this term in Mathematica:

$$\int_{-\infty}^{\infty} d\omega*\sin(s*\omega)*\frac{1}{e^{\beta*\hbar*\omega}-1}*\frac{\omega}{\omega^{2}+\gamma^{2}}$$

The code in Mathematica:

Integrate[Sin[s*ω]*(1/(Exp[β*ℏ*ω] -1))*ω/(ω^2 + γ^2), {ω, -Infinity, Infinity},
  Assumptions -> {ℏ > 0, s >= 0, γ > 0, β > 0}]

The result is:

$\frac{-\pi}{2}*e^{-s*\gamma}$

Where is $\beta*\hbar$?

share|improve this question
1  
The result is correct. The integral does not depend on either $\beta$ or $\hbar$, which is why $\beta\hbar$ does not appear in your answer. –  DumpsterDoofus Jun 10 at 14:00
    
So we could set $\beta$=0 ? –  b.gatessucks Jun 10 at 14:03
    
β>0 is in the Assumptions.. –  george2079 Jun 10 at 14:17

2 Answers 2

up vote 7 down vote accepted

we can see why this happens with a change of variable:

 Integrate[bhw Sin[(bhw s)/bh]/((-1 + E^bhw) (bhw^2 + bh^2 gamma^2)),
       {bhw, -Infinity, Infinity}, Assumptions -> {s >= 0, gamma > 0, bh > 0}]

(same result )

Now change the one instance of bh to a new parameter:

 Integrate[bhw Sin[(bhw s)/bh1]/((-1 + E^bhw) (bhw^2 + bh^2 gamma^2)),
       {bhw, -Infinity, Infinity}, Assumptions -> {s >= 0, gamma > 0, bh > 0,bh1>0}]

-(1/2) E^(-((bh s gamma )/bh1)) Pi

So you see with bh=bh1 they cancel out..

share|improve this answer
    
If we take $\beta$ infinitely small, expand the exponential, and keep the lowest term then the result would be zero. However if we want to take the limit of $\beta ->0$ in the result we won't get zero. –  yashar Jun 10 at 15:01
    
you can change your assumption to β!=0 and readily see there is a discontinuity (change of sign) at zero so that the limit does not exist. –  george2079 Jun 10 at 15:23
    
So I cannot expand the exponential. right? –  yashar Jun 10 at 15:36
2  
You ought to ask on math.stackexchange.com if you want to study why that method of taking the limit isn't working. –  george2079 Jun 10 at 15:49

Another way to see the result is to do it by contour integration.

Start by expanding out the integrand.

(Sin[s omega] omega)/((Exp[beta hbar omega] - 1) (omega^2 + gamma^2)) // TrigToExp // Expand

(*
  (I E^(-I omega s) omega)/(2 (-1 + E^(beta hbar omega)) (gamma^2 + omega^2))
- (I E^(I omega s) omega)/(2 (-1 + E^(beta hbar omega)) (gamma^2 + omega^2))
*)

For s > 0 the first term needs the contour to be closed towards omega = -I Infinity (i.e contributes -2 Pi I times the residue at omega = -I gamma), and the second term needs the contour to be closed towards omega = I Infinity (i.e contributes 2 Pi I times the residue at omega = I gamma).

This gives

-2 \[Pi] I Residue[(I E^(-I omega s) omega)/(2 (-1 + E^(beta hbar omega)) (gamma^2 + omega^2)), {omega, -I gamma}] +
 2 \[Pi] I Residue[-((I E^(I omega s) omega)/(2 (-1 + E^(beta hbar omega)) (gamma^2 + omega^2))), {omega, I gamma}]

(*
  (E^(-gamma s) \[Pi])/(2 (-1 + E^(I beta gamma hbar)))
- (E^(I beta gamma hbar - gamma s) \[Pi])/(2 (-1 + E^(I beta gamma hbar)))
*)

which simplifies thus

% // Simplify

(* -(1/2) E^(-gamma s) \[Pi] *)

The case s = 0 is not covered by the above derivation, but the integral is clearly 0 in this special case.

Edit (to correct an omission pointed out by Daniel Lichtblau in the comments below):

There are also poles where Exp[beta hbar omega] == 1, but these cancel in pairs as follows:

res[m_] = 
  SeriesCoefficient[(
  Sin[s omega] omega)/((Exp[beta hbar omega] - 1) (omega^2 + gamma^2)), {omega, (2 I \[Pi] m)/(beta hbar), -1}, 
  Assumptions -> m \[Element] Integers]

(*
  (2 E^(-2 I m \[Pi]) m \[Pi] Sinh[(2 m \[Pi] s)/(beta hbar)])/(-beta^2 gamma^2 hbar^2 + 4 m^2 \[Pi]^2)
*)

Combine the corresponding residues from poles on the positive and negative imaginary axis, using opposite signs because the contour-completion at +I Infinity or -I Infinity goes round the poles in opposite directions.

res[m] - res[-m] // Simplify[#, Assumptions -> m \[Element] Integers] &

(* 0 *)

So these additional poles do not contribute to the integral.

share|improve this answer
    
Aren't there other poles on the imaginary axis, where Exp[beta hbar omega] == 1? (Maybe those residues sum to zero?) –  Daniel Lichtblau Jun 10 at 23:55
    
Yes, you are right, I overlooked those poles in my haste to post an "answer" that seemed to explain everything. However, I got lucky, because the poles where Exp[beta hbar omega] == 1 cancel in pairs between the positive/negative imaginary axis. –  Stephen Luttrell Jun 11 at 13:10
    
I had also gone down the contour path. You got further than I did-- I didn't do the work to figure out those "main" poles gave a viable result, let alone notice the cancellation amongst the rest. When I saw you had a correct value I just figured something like that must have happened. –  Daniel Lichtblau Jun 11 at 13:38

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.