Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

I would like to create a contour plot of $e^z-\dfrac{z-1}{z+1}$ that looks like the picture on the left, but can only manage the one on the right. I have tried incrreasing the number of contours, but this doesn't have any effect. Am I missing something fundamental?

Show[Table[ContourPlot[{Im[E^(x + I y) - ((x + I y) - 1)/(x + I y) + 1] == k, 
Re[E^(x + I y) - ((x + I y) - 1)/(x + I y) + 1] == k}, {x, -4, 4}, {y, -20, 20}, 
ContourStyle -> {Directive[{Red}], Directive[{Blue}]}, 
PlotPoints -> 100, Contours -> 20, AspectRatio -> Automatic], {k, -10, 10, 2}]]

The plot I am trying to recreate is from this website (specific PDF).

share|improve this question

1 Answer 1

up vote 8 down vote accepted

The main thing you missed was that the picture on the left shows contours of the amplitude and phase, not the real and imaginary parts.

I couldn't get a good result for both sets of contours in one plot, so here I create the two plots separately and combine them with Show:

f[z_] := Exp[z] - (z - 1)/(z + 1)

Show[
 ContourPlot[#1[f[x + I y]], {x, -4, 4}, {y, -20, 20},
    ContourStyle -> #2, Contours -> #3, 
    AspectRatio -> Automatic, ContourShading -> None, PlotPoints -> 30] & @@@ 
   {{Abs, Blue, Exp @ Range[-5, 5]},
   {Arg, Red, Range[-Pi, Pi, Pi/5]}}
]

enter image description here

share|improve this answer
    
Great - that you ! I just tried something different, but you are right, I did miss that - thank you again :) –  martin Jun 8 at 13:27

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.