# Hatched Filling for ListPlot

I am plotting to data curves using ListLinePlot. I like the look of Filling, but this is going to be printed, so I want something both black and white friendly, but giving more definition and separation than changing the opacity of the filling. Ideally, I would either have one hatched and the other filled solid gray, or both hatched in opposite directions or something such that they can be identified separately. This is what I have so far that I may just use if I can't find anything better:

data1 = exPDMIABSA[[1]];
data2 = exPDMIAwater[[1]];
ListLinePlot[{data1, data2},
PlotStyle -> {Black, Directive[Dashed, Black]},
Filling -> Axis,
FillingStyle -> Directive[Opacity[0.7], Gray]]


Three related questions I've found are

RegionPlot (or FillingStyle) using hash lines?

and

Filling a polygon with a pattern of insets

and

How can I make hatching filling of plot

but none seems to address this situation. They seem to be dealing with shapes and (region)plots and not ListPlots. While it is entirely possible that they are very closely related, I'm not sure how to use any of those answers for my situation.

Thanks

-
The image link is broken. – Szabolcs Jun 5 '14 at 21:31
I updated it a few minutes ago, and it seems to be working for me. Is it still not working? Is it possible that my edit hasn't updated yet? @Szabolcs – ThomasH Jun 5 '14 at 21:35
It's working now. Please use's SE's image hosting if possible (I do not know if it's possible for new users). – Szabolcs Jun 5 '14 at 21:48
What I'd try is using the approach shown in the posts you linked, especially the last one. These rely on having a function to plot, not discrete data. You have discrete data, however, you can convert it to a function using Interpolation. Set InterpolationOrder -> 1 if that's what you need (this is what List(Line)Plot does). – Szabolcs Jun 5 '14 at 21:51
@Szabolcs The use of the interpolation function and the last linked question worked well and seemed pretty easy and short to implement. Here is the new figure. – ThomasH Jun 6 '14 at 13:21

This is what I've ended up doing.

data1 = exPDMIABSA[[1]];
data2 = exPDMIAwater[[1]];
Show[ListLinePlot[{data1, data2},
PlotStyle -> {Directive[Dashed, Black], Black},
Filling -> {2 -> Axis}, FillingStyle -> Gray],
RegionPlot[
y < Interpolation[data1, InterpolationOrder -> 1][x] && y > 0, {x,
300, 375}, {y, 0, 17000}, Mesh -> 50, MeshFunctions -> {1000 #1 - #2 &},
BoundaryStyle -> None, MeshStyle -> Thickness[.005],
PlotStyle -> Transparent]]


The RegionPlot is based on this question after a suggestion in the comments to the question by Szabolcs.

Of course the same could be done for the other region in the opposite direction by switching the sign in the MeshFunctions. Also, because of the scale, the slope of the MeshFunctions was changed. The number of hatchings can be changed by changing Mesh. The default lines were a little thin for me so I thickened them with MeshStyle -> Thickness[.005].

For certain circumstances, it might be easier to define interpolation functions for each data set such as data1func = Interpolation[data1, InterpolationOrder -> 1] and just Plot that.

To me this seemed a little simpler, faster, and more general than the answer by Kuba to this question.

-

This is not the fastest way but I think it is fast and short enough. And, first of all, clear.

dat = RandomReal[2, 10];
dat2 = RandomReal[2, 10];
poly = ListLinePlot[{dat, dat2}, Filling -> Axis, PlotStyle -> GrayLevel@.5
] // Normal // Cases[#, Polygon[x_] :> x, \[Infinity]] &;

inPolyQ[poly_, pt_] := GraphicsMeshPointWindingNumber[poly, pt] =!= 0

With[{copt = Sequence[MaxRecursion -> 1, PlotPoints -> 100, BoundaryStyle -> Black,
Mesh -> {Range[0, 15, .1]}, MeshStyle -> Black, PlotStyle -> None]},
Show[
Quiet@RegionPlot[ inPolyQ[poly[[1]], {x, y}], {x, 0, 11}, {y, -.1, 2.1},
MeshFunctions -> {# + #2 &}, copt],
Quiet@RegionPlot[ inPolyQ[poly[[2]], {x, y}], {x, 0, 11}, {y, -.1, 2.1},
MeshFunctions -> {# - #2 &}, copt],
AspectRatio -> Automatic, ImageSize -> 600]]


Based on:

and

-
Thanks @Kuba! That is a pretty graphic. I think I'll go with @Szabolcs suggestion in the comments to the question as that seems easier to me, and I understand it better. I might just post it as my own answer for others who might be wondering. – ThomasH Jun 6 '14 at 13:25
@ThomasH sure, feel free to accept you own answer, it seems to be better indeed ;) – Kuba Jun 6 '14 at 13:54