Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

I'm trying to use Manipulate for plotting multidimensional data, where higher dimensions are defined as sliders.

First, this simple example works:

myfun[v1_Real, v2_Real, v3_Real, v4_Real, v5_Real] := 
 Sin[v1]*Cos[v2]*v3 + v4*v5

Manipulate[
 Plot3D[myfun[v1, v2, v3, v4, v5], {v1, 0, 2}, {v3, 0, 2}], {{v5, 
   0.5}, 0., 1.}, {{v2, 0.5}, 0., 1.},(*{{v3,0.5},0.,1.},*){{v4, 0.5},
   0., 1.}]

Mathematica graphics

But when the dimensions for plotting and for controls are configured to change dynamically, then Mathematica gets stuck:

Manipulate[
 With[{myaxis = Sequence @@ {{v[ax1], 0, 2}, {v[ax2], 0, 2}}, 
   mycontrols = 
    Sequence @@ {{{v[sl1], 0.5}, 0., 1.}, {{v[sl2], 0.5}, 0., 
       1.}, {{v[sl3], 0.5}, 0., 1.}}}, 
  Manipulate[Plot3D[myfun[v[1], v[2], v[3], v[4], v[5]], myaxis], 
   mycontrols]], {ax1, Range[1, 4, 1], ControlType -> Setter}, {ax2, 
  Range[ax1 + 1, 5, 1], ControlType -> Setter}, {sl1, 
  Complement[Range@5, {ax1, ax2}], ControlType -> Setter}, {sl2, 
  Complement[Range@5, {ax1, ax2, sl1}], ControlType -> Setter}, {sl3, 
  Complement[Range@5, {ax1, ax2, sl1, sl2}], ControlType -> Setter}]

Mathematica graphics

How can I make the last piece of code to evaluate correctly?

share|improve this question
1  
Related Q/A? –  kguler Apr 28 at 22:42
    
I used similar example Nesting Manipulate, but my problem is not covered in these toturials –  denfromufa Apr 28 at 22:58
1  
Also relevant ? –  b.gatessucks Apr 29 at 10:08
    
b.gatessucks, this thread is related, but not tested with sliders for variables not used for axes –  denfromufa Apr 29 at 22:42

1 Answer 1

up vote 4 down vote accepted

This isn't quite what you asked, but it is hopefully giving the required result. The whole nested Manipulate with changing controls seemed like a can of worms to me.

Manipulate[
 If[oldax1 != ax1 || oldax2 != ax2,
  If[ax1 == ax2, ax2 = Mod[ax1, 5] + 1];
  oldax1 = ax1; oldax2 = ax2;
  set[ax1, ax2]];
 Plot3D[f[{a, b, c, v1, v2}], {v1, 0, 2}, {v2, 0, 2}],

 {{ax1, 1, ""}, {1, 2, 3, 4, 5}}, {{oldax1, 1}, None},
 {{ax2, 2, ""}, {1, 2, 3, 4, 5}}, {{oldax2, 1}, None},
 {{a, 0.5}, 0., 1.}, {{b, 0.5}, 0., 1.}, {{c, 0.5}, 0., 1.},
 {{sl1, 3}, None}, {{sl2, 3}, None}, {{sl3, 3}, None},
 Dynamic@f[{a, b, c, v1, v2}],
 Initialization -> {
   Clear[set, f];
   set[a1_, a2_] :=
     (ax1 = a1; ax2 = a2;
      With[{other = Complement[Range@5, {ax1, ax2}]}, 
       sl1 = other[[1]]; sl2 = other[[2]]; sl3 = other[[3]]];
      f[v_] := myfun[Permute[v, {sl1, sl2, sl3, ax1, ax2}]]
      );
   }]

1

There is no longer any changing controls, instead we just select which of the variables we plot against. These are fed into myfun by permuting the order of the variables (now passed a list instead of a sequence).

There are a few other tricks in here, which I might explain later if there is any interest.

share|improve this answer
    
That's a nice answer! +1 –  rasher Apr 29 at 6:52
    
I commented out Dynamic@f[{a, b, c, v1, v2}], because it shows the long expression within the function –  denfromufa Apr 29 at 15:37
    
one problem with this approach is that you mess up values of variables when dimensions switch from sliders to axes –  denfromufa Apr 30 at 20:43
    
@denfromufa I'm not sure what you mean by that. Can you explain further? –  wxffles May 1 at 0:19

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.