Changing the order of elements in a chart legend

Question

In a stacked BarChart or Histogram the bars are stacked from bottom to top, while the legend entries are listed from top to bottom. Is there a way to make the legend entries go the other way round to improve the visual correspondence between the chart and the legend?

E.g.

{bottom,middle,top}=RandomReal[NormalDistribution[0,1],{3,200}];
Histogram[{bottom,middle,top},10,ChartLayout->"Stacked",ChartLegends->{"Bottom","Middle","Top"}]

Answer 1

Histogram[{bottom, middle, top}, 10, 
          ChartLayout -> "Stacked", 
          ChartLegends -> {"Bottom", "Middle", "Top"}] /. 
Column[l_List] :> Column[Reverse@l]

Answer 2

Using belisarius' method, if you want to reverse the order for all vertical legends you could use Legending`LegendContainer like this:

{bottom, middle, top} = RandomReal[NormalDistribution[0, 1], {3, 200}];

SetOptions[Legending`GridLegend, 
  Legending`LegendContainer -> (Framed[# /. Column[l_List] :> Column[Reverse@l]] &)
];

Histogram[{bottom, middle, top}, 10,
  ChartLayout -> "Stacked",
  ChartLegends -> {"Bottom", "Middle", "Top"}
]

Answer 3

belisarius beat me to the Column replacement rule method. An alternative method would be to use ShowLegend to construct the legend manually, taking the code for the layout from the FullForm of your original graphic. The ridiculously complex lokking color specifications happen to be the Mathematica defaults for bar charts.

ShowLegend[ Histogram[{bottom, middle, top}, 10,  ChartLayout -> "Stacked"], 
 {{{Graphics[{GrayLevel[0.9], 
      Directive[GrayLevel[0.85], EdgeForm[Opacity[0.7]], Opacity[0.5],
        RGBColor[0.6, 0.5470136627990908, 0.24]], 
      Rectangle[{0, 0}, {1, 1}]}, {ImageSize -> 10}], 
    "Top"}, {Graphics[{GrayLevel[0.9], 
      Directive[GrayLevel[0.85], EdgeForm[Opacity[0.7]], Opacity[0.5],
        RGBColor[0.6, 0.24, 0.4428931686004542]], 
      Rectangle[{0, 0}, {1, 1}]}, {ImageSize -> 10}], 
    "Middle"}, {Graphics[{GrayLevel[0.9], 
      Directive[GrayLevel[0.85], EdgeForm[Opacity[0.7]], Opacity[0.5],
        RGBColor[0.2472, 0.24, 0.6]], 
      Rectangle[{0, 0}, {1, 1}]}, {ImageSize -> 10}], "Bottom"}}, 
  LegendPosition -> {0.25, 0.2}, LegendBackground -> White, 
  LegendBorder -> None, LegendShadow -> None, 
  LegendSize -> {0.6, 0.35}, LegendBorder -> None, 
  LegendTextSpace -> 3}]

Answer 4

This solution will no longer work in Mathematica 9 because they now use SwatchLegend in FullForm. Instead, apply this:

Histogram[{bottom, middle, top}, 10, ChartLayout -> "Stacked", 
ChartLegends -> {"Bottom", "Middle", "Top"}] /. 
SwatchLegend[l1_List, l2_List, r1_Rule, r2_Rule] :> 
SwatchLegend[Reverse[l1, 1], Reverse[l2, 1], r1, r2]

The integer parameter in Reverse[l1,1] and Reverse[l2,1] might have to be tweaked; in some cases I had to reverse within the second level instead of the first. //FullForm should give you enough hints.