Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

Is there a way to enter the traditional form of a binomial coefficient, i.e. ${n \choose k}$ instead of Binomial[n,k], like I would enter a radical sign $\sqrt{x}$ using control-shift-2? I would like to enter it that way in a notebook, and see it in that form in the input as well as output equations, just like the radical. I know that I can use TraditionalForm to convert it on output, but I don't need to do that to see radicals instead of Sqrt.

share|improve this question

1 Answer 1

up vote 9 down vote accepted

You could do it using the following:

SetOptions[EvaluationNotebook[],InputAliases->{"bn"->
 FormBox[TemplateBox[{"\[SelectionPlaceholder]",
  "\[Placeholder]"},"Binomial"],InputForm]}]

Then enter escbnesc to get a placeholder that you can tab through:

pic

Then enter the numbers and press shift-enter to evaluate.

Edit

To make the output appear formatted without invoking TraditionalForm, you'd have to define a wrapper function and its style:

ClearAll[myBinomial]

appearance[x_, y_] := TemplateBox[{x, y}, "myBinomial",
  DisplayFunction :> (RowBox[{"(", "\[NoBreak]", 
       GridBox[{{#1}, {#2}}, RowSpacings -> 1, ColumnSpacings -> 1, 
        RowAlignments -> Baseline, ColumnAlignments -> Center], 
       "\[NoBreak]", ")"}] &), 
  InterpretationFunction :> (RowBox[{"myBinomial", "[", 
       RowBox[{#1, ",", #2}], "]"}] &)
  ]

SetOptions[EvaluationNotebook[], InputAliases -> {"bn" ->
    appearance["\[SelectionPlaceholder]", "\[Placeholder]"]
   }]

myBinomial[n_?NumericQ, k_?NumericQ] := Binomial[n, k]

myBinomial /: MakeBoxes[myBinomial[n_, k_], StandardForm] := 
 appearance[ToBoxes[n], ToBoxes[k]]

Now the template appears as before, but when the function arguments aren't numerical, it's also displayed in 2D form. One could add additional definitions to myBinomial depending on what cases you want the 2D display to apply to. Whenever there is no definition for myBinomial, it is left unevaluated and will be displayed in the formatted style.

share|improve this answer
    
Awesome! Though it comes out as Binomial[n,k] if it's not numbers. Can I get it to display in the traditional form without having to use TraditionalForm? –  Mark Adler Apr 7 at 5:30
    
@MarkAdler Yes you can do that, too, but I wouldn't recommend it. To make the output behave differently, one would have to do something similar to what I did in this answer, but for StandardForm. It would require defining a wrapper function myBinomial so you don't have to modify the protected Binomial itself. Then the Format for that wrapper function can be defined to be what you want. I'll leave it up to you to adapt that other answer, since this question was only about input. –  Jens Apr 7 at 5:55
    
I'll look at that. Thanks. By the way, this question was also about the output. You'd have to read the entire body of the question. The title of the question is abbreviated and necessarily incomplete. –  Mark Adler Apr 7 at 6:06
    
@MarkAdler Ah, I thought you'd be OK with a display that only works in TraditionalForm. I added something to make it work in StandardForm. –  Jens Apr 7 at 14:47
    
Awesome squared. Works like a charm. Thank you. –  Mark Adler Apr 7 at 22:32

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.