Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

My question here is fairly basic, and I'm sure I'm overlooking something basic. I know about CountryData for creating shapes of entire countries, and it works, to an extent; I can plot geographical data on it with the coordinates, but I'd like to have a magnified view of a state alone. The goal is to be able to measure borderlines. Is there built-in functionality for this, or do I have to import a shape file of a state?

share|improve this question
    
Related: Mathematica North America map. –  Andrew Cheong Mar 22 at 2:27
    
You'll need shape files. Another similar question is this one –  bobthechemist Mar 22 at 3:17

1 Answer 1

There is no built in option, however for the US it's very easy because the coordinates of the state borderlines are all over the Internet. This led me to one such data set. I'll include how I cleaned it up, like this:

data = Import["http://econym.org.uk/gmap/states.xml"];
name[{"name" -> n_, ___}] := n
coordinates[XMLElement["point", {"lat" -> lat_, "lng" -> lng_}, {}]] := {lat, lng}
states = 
  {name@Part[#, 1], coordinates /@ Part[#, 2]} & /@ 
    Partition[Cases[data, XMLElement["state", state__] :> state, Infinity], 2];

However there is no point in redoing those things over and over. You might as well define states like this (the link leads to Pastebin where the list of coordinates is available. The list is too large to post here.)

To draw a specific state you can do something like this:

state[name_] := states /. {___, {name, pts_}, ___} :> (ToExpression /@ pts)

ImageReflect[ImageRotate[Graphics[{
    RGBColor[0.896, 0.8878, 0.8548], EdgeForm[GrayLevel[0]], 
    Polygon[state["Indiana"]],
    PointSize[Medium], Red,
    Point[CityData[{"Clinton", "Indiana", "United States"}, "Coordinates"]],
    Point[CityData[{"Indianapolis", "Indiana", "United States"}, "Coordinates"]]
    }], Pi/2], Right]

Indiana

Of course you will be able to design better utility functions than I have to stuff away operations such as ImageReflect and ImageRotate.

Just another example to show how this can be used to draw the US map in it's entirety. You could very easily style each state individually.

ImageReflect[ImageRotate[Graphics[{
    RGBColor[0.896, 0.8878, 0.8548], EdgeForm[GrayLevel[0]], 
    Polygon[state[First@#] & /@ (
       states /. {
         {"Hawaii", __} -> Sequence[],
         {"Alaska", __} -> Sequence[]
         }
       )],
    PointSize[Medium], Red,
    Point[CityData[{"Clinton", "Indiana", "United States"}, "Coordinates"]],
    Point[CityData[{"Indianapolis", "Indiana", "United States"}, "Coordinates"]]
    }], Pi/2], Right]

enter image description here

(I know your purpose is not visualization, but someone will surely come along sooner or later looking for how to do visualization.)

share|improve this answer
    
Thank you so much! I had already worked out a similar approach before your answer, in part from the comments above, but this has helped streamline it a bit. Just as a side question, is there any way to make your two points above different sizes in the same Graphics function? –  Smith W. Mar 23 at 2:18
    
@SmithW. Yes, you can easily change the settings in between graphics primitives, for example {Red, PointSize[Small], Point[{0,0,0}], Green, PointSize[Large], Point[{1,0,0}]} creates two different points with different colors and sizes. Look up PointsSize to see how you can specify different sizes. –  Pickett Mar 23 at 2:31

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.