Number of iterations in NSolve

Question

In Excel's solver, one can define how many iterations are to be done, to one's liking.

I am wondering if this is possible to do with NSolve in Mathematica?

Code

This is what I'm working with:

A = 3580/1000; (*constante*)
B = 736/1000;(*constante*)
R1 = 5/1000;(*0-1.5*)
R2 = 17/1000;(*0-1.5*)

fR1 = ((A + B) (1 - a)^2 (1/15 + P2/21 - (4 P4)/35))/
    (A (1/15 (3 + 4 a + 8 a^2) + 4/21 (3 + a - 4 a^2) P2 + 
      8/35 (1 - a)^2 P4) + B (1 - a)^2 (1/15 + P2/21 - (4 P4)/35));
fR2 = (A (1 - a)^2 (1/15 + P2/21 - (4 P4)/35) + B (1 - a)^2 (1/15 - (2 P2)/21 + P4/35))/
    (A (1/15 (3 + 4 a + 8 a^2) - 2/21 (3 + a - 4 a^2) P2 + 
      3/35 (1 - a)^2 P4) + B (1 - a)^2 (1/15 - (2 P2)/21 + P4/35));
fP4 = -((83 P2)/1000) + (1366 P2^2)/1000 - (1899 P2^3)/1000 + (1616 P2^4)/1000;
fRho = ((A + B) (1 - a)^2)/(A (8 a^2 + 4 a + 3) + B (1 - a)^2);

NSolve[R1 == fR1 && R2 == fR2 && P4 == fP4 && rho == fRho, {P2, P4, a, rho}, Reals];
MatrixForm[%]

Answer 1

The main algorithm behind NSolve is, I believe, the Jenkins-Traub algorithm, which is indeed iterative in nature. I don't believe that you can specifiy the number of iterates directly, however. Isn't it better to specify the desired precision, though? Mathematica tries to find the solution to a certain precision, and you can specify the precision that you want, as in

eqs = {R1==fR1, R2==fR2, P4==fP4, rho==fRho};
sols= NSolve[eqs, {P2, P4, a, rho}, Reals,
  WorkingPrecision -> 20];

You can always check the quality of the results, as well, using something like so:

(#[[1]] - #[[2]] & /@ eqs) /. sols

This will let you know exactly how close you are on each equation.

Answer 2

From this documentation page,

"For systems of algebraic equations, NSolve computes a numerical Gröbner basis using an efficient monomial ordering, then uses eigensystem methods to extract numerical roots."

When one restricts to work over the reals this is no longer necessarily how it is done. In any case, NSolve is not using iterative methods. (In particular it is not using Jenkins-Traub, because that only applies to univariate polynomials.) Upshot: One cannot limit the iterations. Also I'll confirm that for polynomial systems (or rational functions), NSolve does in fact find all solutions (barring extreme numerical instability).

About the WorkingPrecision option. It does not do much to guarantee the precision of the output. It can be used to force high precision. This can be helpful in cases where the eigensystem extraction is not well behaved, or where high precision is really needed to get small residuals due to instability of the inputs. (How might one know? By checking the results from running NSolve without setting that option, and noticing fairly large residuals.)