Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

I have been trying to do the following series:

Series[HypergeometricPFQ[{1, 4, 4}, {4 - Sqrt[3], 4 + Sqrt[3]}, z],{z,1,0}]

Mathematica says that the result is infinite, without telling me precisely how it diverges with 1-z. I have tried FunctionExpand, FullSimplify and other commands, but so far, with no success. Any help would be most welcome.

Best, Jorge

share|improve this question

1 Answer 1

Probably because it has a rather complicated branch point at z=1. It is actually very easy to derive the explicit expansion:

singular[x_] = Csc[Sqrt[3] Pi] (-I Sqrt[3] Pi^2 + Pi (1 + 1/(Sqrt[3] (-1 + x)))
- 2 Sqrt[3] Pi HarmonicNumber[Sqrt[3]] - Sqrt[3] Pi Log[-1 + x]);  

finite[x_] = (3 - 2 Sqrt[3]) HypergeometricPFQ[{1, 4, Sqrt[3]}, 
{2 + Sqrt[3], 4 + Sqrt[3]}, 1];

suppressed[x_] = (x - 1) 16/ 13 (-69 + 40 Sqrt[3])
HypergeometricPFQ[{2, 5, Sqrt[3]}, {3 + Sqrt[3], 5 + Sqrt[3]}, 1]
+ (x - 1) 1/2 Pi Csc[Sqrt[3] Pi] (-10 - 9 Sqrt[3] + 10 I Sqrt[3] Pi
+ 20 Sqrt[3] HarmonicNumber[Sqrt[3]] + 10 Sqrt[3] Log[-1 + x]);

asymp[x_] = singular[x] + finite[x] + suppressed[x] (* + O((x-1)^2 Log[x-1]) *);

Notice the logarithmic function in the singular part. Here is the comparison with the original function:

y = 10^-8;
N[HypergeometricPFQ[{4, 4, 1}, {4 + Sqrt[3], 4 - Sqrt[3]}, 1 + y] - asymp[1 + y], 16]

(* -1.892181059711013*10^(-13) + 3.39982418261034*10^(-13) I *)

Derivation

I derived this result by using the integral representation of a generalized hypergeometric function:

integral representation

integral = HypergeometricPFQ[{a_, b_, c_}, {d_, e_}, x_] :> 
Gamma[e]/(Gamma[c] Gamma[e - c]) z^(c - 1) (1 - z)^(e - c - 1) Hypergeometric2F1[a, b, d, x z];

You can easily check it:

Integrate[ Gamma[e]/(Gamma[c] Gamma[e - c]) z^(c - 1) (1 - z)^(e - c - 1)
Hypergeometric2F1[a, b, d, x z], {z, 0, 1}, Assumptions -> Re[c] < Re[e] && Re[c] > 0]

(* HypergeometricPFQ[{a, b, c}, {d, e}, x] *)

Secondly, I applied a simple transformation rule for the integrand:

transformation of the hypergeometric function

hyperTransform = HoldPattern[Hypergeometric2F1[a_, b_, c_, z_]] :> 
(Gamma[c] Gamma[c - a - b])/(Gamma[c - a] Gamma[c - b]) 
Hypergeometric2F1[a, b, a + b - c + 1, 1 - z] 
+ (1 - z)^(c - a - b) (Gamma[c] Gamma[a + b - c])/(Gamma[a] Gamma[b]) 
Hypergeometric2F1[c - a, c - b, c - a - b + 1, 1 - z];

Thus, I obtained the following integrand:

Collect[HypergeometricPFQ[{4, 4, 1}, {4 + Sqrt[3], 4 - Sqrt[3]}, x] 
/. integral /. hyperTransform, _Hypergeometric2F1, Composition[PowerExpand, FullSimplify]]

which is the sum of two terms:

-Pi x^(-3 + Sqrt[3]) (1 - z)^(-1 + Sqrt[3]) z^Sqrt[3] (1 - x z)^(-1 - Sqrt[3]) Csc[Sqrt[3] Pi] 
- (3 + 2 Sqrt[3]) (1 - z)^(-1 + Sqrt[3]) z^3 Hypergeometric2F1[1, 4, 2 + Sqrt[3], 1 - x z]

For the second part, the series expansion about x=1 commutes with the integration with respect to z, hence you can expand it and then integrate, e.g, the leading term is (I made a substitution z-> 1-z)

Integrate[ -(3 + 2 Sqrt[3]) z^(-1 + Sqrt[3]) (1 - z)^3 Hypergeometric2F1[1, 4, 2 + Sqrt[3], z], 
{z, 0, 1}]

(* (3 - 2 Sqrt[3]) HypergeometricPFQ[{1, 4, Sqrt[3]}, {2 + Sqrt[3], 4 + Sqrt[3]}, 1] *)

The first term you need to integrate first and then expand:

Integrate[-Pi x^(-3 + Sqrt[3]) (1 - z)^(-1 + Sqrt[3]) z^Sqrt[3] 
(1 - x z)^(-1 - Sqrt[3]) Csc[Sqrt[3] Pi], {z, 0, 1}, Assumptions -> Im[x] != 0]

(* -((4^-Sqrt[3] Pi^(3/2) x^(-3 + Sqrt[3]) Csc[Sqrt[3] Pi] Gamma[Sqrt[3]] 
Hypergeometric2F1[1 + Sqrt[3], 1 + Sqrt[3], 1 + 2 Sqrt[3], x])/Gamma[1/2 + Sqrt[3]]) *)

FullSimplify[Normal@Series[%, {x, 1, 0}], Assumptions -> x > 1 && Arg[x] == 0]

Thus, you can find any term of the expansion.

share|improve this answer

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.