How to extract edgeweights from a graph

Question

I have a graph with weighted edges, and I'd like to obtain the edge weights of the edges in the graph. Is there a nicer way of doing this than getting the WeightedAdjacencyMatrix of the graph? A list of weights that's 1-1 with the EdgeList of the graph would be great.

Answer 1

You can still use WeightedAdjacencyMatrix and massage the output to a nicer form —

g = Graph[{1 <-> 2, 2 <-> 3, 3 <-> 1}, EdgeWeight -> {2, 3, 4}];
Replace[Most@ArrayRules@UpperTriangularize@WeightedAdjacencyMatrix[g], 
    {x_, y_} :> UndirectedEdge[x, y], {2}]

Answer 2

g = Graph[{1 <-> 2, 2 <-> 3, 3 <-> 1}, EdgeWeight -> {2, 3, 4}];
AbsoluteOptions[g, EdgeWeight] /. HoldPattern[EdgeWeight -> x_] -> x

Answer 3

Using PropertyValue[g,property] and Thread or Map:

    g = Graph[{1 <-> 2, 2 <-> 3, 3 <-> 1}, EdgeWeight -> {2, 3, 4}];
    Thread[EdgeList[g] -> PropertyValue[g, EdgeWeight]] 
    Map[# -> PropertyValue[{g, #}, EdgeWeight] &, EdgeList[g]]

both give:

Similarly, use

   Thread[{EdgeList[g], PropertyValue[g, EdgeWeight]}] 
   Map[{#, PropertyValue[{g, #}, EdgeWeight]} &, EdgeList[g]]

to get a list: