Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

% allows to refer to the result of the preceding calculation (preceding in time) but this seems not necessarily to be the cell just above a given cell.

How can one refer to the result of the cell just above ?

share|improve this question
1  
You can use the index of the output to refer to it. For example, if it's Out[32] you can refer to it by %32. –  xzczd Feb 4 at 11:10
    
yes, but that number seems also to depend on the order I evaluate cells (which is not necessarily from top to bottom) and it also changes when evaluate a cell a second time (e.g. after changing something) –  Andre Holzner Feb 4 at 11:35
1  
Yeah, the number depends on the evaluation order. If you need to use the output of a specified cell for times, it's better to give a name to it. –  xzczd Feb 4 at 11:47
add comment

2 Answers 2

up vote 13 down vote accepted

You can use something like this. (I have added extra steps to demonstrate practical usage.)

enter image description here

Selectable code

x = 3

y = x + 2;
Clear[x, y, z]
SelectionMove[EvaluationNotebook[], Previous, Cell, 3];
z = ToExpression@First@NotebookRead[EvaluationNotebook[]];
y + z

Addendum

Further to xzczd's comment, you can also use a cell tag :-

enter image description here

share|improve this answer
    
great ! It looks like one can even define a 'function' prevCell := Module[{}, SelectionMove[...]; Return[ToExpression@...];] –  Andre Holzner Feb 4 at 12:06
2  
(+1) Current implementation SelectionMove[EvaluationNotebook[], Previous, Cell, 3]; fails when the evaluation cell has already printed some output(s). More reliable approach would be SelectionMove[EvaluationNotebook[],Before,EvaluationCell]; SelectionMove[EvaluationNotebook[],Previous,Cell,1];. –  Alexey Popkov Feb 4 at 12:16
    
@AlexeyPopkov - Yes, that works nicely. –  Chris Degnen Feb 4 at 13:15
add comment

Version 9 offers a couple of new ways to access cells that are useful to meet the needs of this question.

The first way involves the use of the Cells and EvaluationCell functions. They can be used in the present context like this:

previousCell[] :=
  Cells @ EvaluationNotebook[] /. {___, prev_, EvaluationCell[], ___} :>
    ToExpression @ First @ NotebookRead @ prev

Here, we retrieve all cells from the evaluation notebook and use pattern matching to find the cell prior to the currently evaluating cell. Having recovered that cell object, we extract its box representation and convert it to an expression. Proper error- and boundary-checking are left as exercises for the reader. This method's use of pattern-matching can be helpful if more elaborate conditions are needed to identify the sought cell.

A second approach is to use the undocumented function Experimental`ToCellIndex and its companion Experimental`FromCellIndex:

previousCell2[] :=
  ToExpression @ First @ NotebookRead @
    Experimental`FromCellIndex[Experimental`ToCellIndex @ EvaluationCell[] - 1]

The index of the evaluating cell is recovered using FromCellIndex, decremented, and then converted back to a cell object using ToCellIndex. The cell contents are then extracted using the same method as in previousCell. This method is more direct in that it operates upon cell indices, but lacks the flexibity of the earlier pattern-matching approach. Also, these experimental functions simply use Cells internally, so they do not offer any speed-up over direct use of that function.

screenshot of sample use

Edit

As @Jacob Akkerboom notes in the comments, the Experimental package has more cell helper functions. Of particular interest is Experimental`PreviousCell[] which, by default, returns the cell immediately prior to the evaluation cell, i.e. exactly what is requested by this question (how did I miss that in my initial response?). The full signature of that function is essentially equivalent to:

Experimental`PreviousCell[cell_CellObject:EvaluationCell[], style_:All, n_Integer:1]

cell is the reference cell. style names the style of cells to consider when counting, with All meaning all styles. n is how many cells to count backwards to locate the target cell. There is also Experimental`NextCell[] which operates in similar fashion but in the forward direction.

The implementations of Experimental`NextCell and Experimental`PreviousCell (and the other experimental cell functions) are all based upon the Cells function.

share|improve this answer
    
Great :) thanks for the latter but also for the neat former one because I was doing it in more complex way, till now. –  Kuba Feb 5 at 7:20
1  
Maybe Experimental'NextCell can be useful. You can remove its attribute ReadProtected and use Information to see how it works (which is also the case for FromCellIndex and ToCellIndex ). –  Jacob Akkerboom Feb 12 at 11:35
add comment

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.