Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

Any idea how to solve analytically this integral

Integrate[(a Erf[a Sqrt[b/(a^2 + b)] c])/(a^2 + b)^(3/2), a]

I tried substitution u=a^2 + b, but it didn't work. I don't need numerical integration or to solve via the few terms of the Taylor expansion. This seems to be very difficult to solve, but maybe somebody has got an idea.

share|improve this question
    
The answers to this question might shed some light on the issue: Numerical underflow for a scaled error function. –  Artes Feb 3 at 0:16
add comment

1 Answer 1

up vote 3 down vote accepted

Some integrals cannot be found in terms of a finite set of functions. I'm not an expert on what the limits of Mathematica are, but the following suggests to me that this integral is beyond them.

The reason comes down, by a sequence of substitutions, to the fact that this integral returns unaltered:

-Integrate[Erf[Sqrt[1 - w^2]], w]
(*
  -Integrate[Erf[Sqrt[1 - w^2]], w]
*)

The sequence of substitutions

integrand = (a Erf[a Sqrt[b/(a^2 + b)] c])/(a^2 + b)^(3/2) Dt[a];
sub = Solve[u == a Sqrt[b/(a^2 + b)], a]
(*
  {{a -> -((Sqrt[b] u)/Sqrt[b - u^2])}, {a -> (Sqrt[b] u)/Sqrt[b - u^2]}}
*)

int2 = Simplify[
  integrand /. Last@sub,
  Dt[b] == 0 && b > 0 && c > 0 && u > 0]
(*
   (u Sqrt[1/(b - u^2)] Dt[u] Erf[c u])/b
*)

sub3 = Solve[w^2 == b - u^2, u]
(*
  {{u -> -Sqrt[b - w^2]}, {u -> Sqrt[b - w^2]}}
*)

int3 = Simplify[
  int2 /. Last@sub3,
  Dt[b] == 0 && b > 0 && c > 0 && w > 0]
(*
  -((Dt[w] Erf[c Sqrt[b - w^2]])/b)
*)

Integrate[int3 /. Dt[w] -> 1, w]
(*
  -(Integrate[Erf[c Sqrt[b - w^2]], w]/b)
*)

This last integral is nearly the same as the first one. Somehow I tend to believe that if the integral could be done, Mathematica would do it.

share|improve this answer
add comment

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.