Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

I have calculated several homogeneous polynomials in 4,5 or 6 variables $t_1,\dots,t_6$.
I would like to rewrite them as a sum of products of specific lower degree polynomials, which have a meaning in the problem I'm solving.

For example, the simplest polynomial I have is $$ P_4(t_1,t_2,t_3,t_4) = t_1t_2+t_1(t_3+t_4)+t_2(t_3+t_4) $$ which I would like to express in terms of $t_1+t_2, t_2+t_3+t_4, t_1+t_3+t_4$ (only them, although not necessarily all of them). For example, it's easy to see that $$P_4(t_1,t_2,t_3,t_4) = (t_1+t_2)(t_2+t_3+t_4) - t_2^2$$ but I'd prefer something like $$P_4(t_1,t_2,t_3,t_4) = a(t_1+t_2)(t_2+t_3+t_4) + b(t_1+t_2)(t_1+t_3+t_4) + c(t_1+t_3+t_4)(t_2+t_3+t_4)$$

Question: Is there a way to ask Mathematica this sort of partial factorization?

Thank you in advance!

Note: I don't know if a solution exists for my exact polynomials (maybe I have to search for a different interpretation), but I think the general problem is interesting in its own right.

share|improve this question
3  
If it's just the coefficient you're after, that is you guess the factorization, you could try SolveAlways[ t1 t2 + t1 (t3 + t4) + t2 (t3 + t4) == a (t1 + t2) (t2 + t3 + t4) + b (t1 + t2) (t1 + t3 + t4) + c (t1 + t3 + t4) (t2 + t3 + t4), {t1, t2, t3, t4}]. –  b.gatessucks Nov 6 '13 at 10:58
2  
Try e.g. p1 /. Solve[{p1==x y+x (w + z)+y (w + z), q==x+y, p==y+w+z, r==x+w+z}, {p1}, {x, y, w, z}] // Simplify or e.g. GroebnerBasis[{x y + x (w + z) + y (w + z), x + y - q, y + w + z - p, x + w + z - r}, {p, q, r}, {x, y, w, z}] // Simplify. Take a look at these answers Am I missing anything? and How to replace every possible A+B and AB in ... –  Artes Nov 6 '13 at 13:26
    
Thanks for your suggestions! =) –  Andrea Orta Nov 8 '13 at 13:47

1 Answer 1

up vote 4 down vote accepted

This is a variant on the suggestion by @Artes. We start by defining a set of substitutions, using some new variables. Create a Groebner basis. Not to worry if that's not a familiar concept, suffice it to say that we use it for purposes of algebraically rewriting polynomials. The thing to know is that the old variables are to be given greater priority than the new, so that they will be rewritten in terms of the "lower" new variables. This is done simply by listing them first, because by default GroebnerBasis will treat them lexicographically by list position. (I'm skimping on what this all means but the code shows what one should actually do.)

subs = {y1 -> (t1 + t2), y2 -> (t2 + t3 + t4), y3 -> (t1 + t3 + t4)};
subspolys = subs /. Rule -> Subtract;
vars = {t1, t2, t3, t4, y1, y2, y3};
gb = GroebnerBasis[subspolys, vars];

Here is your example.

p4 = t1*t2 + t1*(t3 + t4) + t2*(t3 + t4);

We rewrite it as below, using the substitution rules to replace {y1,y2,y3} by the original t variables.

PolynomialReduce[p4, gb, vars][[2]] /. subs

(* Out[17]= -(1/4) (t1 + t2)^2 + 1/2 (t1 + t2) (t1 + t3 + t4) - 
 1/4 (t1 + t3 + t4)^2 + 1/2 (t1 + t2) (t2 + t3 + t4) + 
 1/2 (t1 + t3 + t4) (t2 + t3 + t4) - 1/4 (t2 + t3 + t4)^2 *)

Notice that this is not quite in the form you wrote. One issue is that there is not necessarily a unique way to rewrite p4 in terms of the "new" variables. Moreover it is quite possible that no term order will give a rewrite that corresponds to the desired one even if such a rewrite exists. But this should at least give an idea of how to get close to the desired form. (I note moreover that, per B.GS, one cannot obtain exactly the form you showed.)

share|improve this answer
    
I remember when I first met groebner bases in abstract algebra lectures many many years ago. It was for the first time I had this "it's like magic" situation in mathematics. It is actually a pity that I oftenly overlook this approach completely. Turn polynomials into algebra, from my opinion the most elegant discipline, and tackle them from easy to understand techniques. Thank you for repeatedly bring them up. –  Stefan Nov 6 '13 at 17:34
    
Thank you very much for the clear explanation, Daniel! =) –  Andrea Orta Nov 8 '13 at 13:47

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.