How to replace the style of the inline cell in a StyleSheet

Question

I would like to change a StyleSheet in such a way that any text that is typed into the inline cell (the one created by Ctrl+9) is shown in a different font (e.g. the font of my choice). At present I do not see, what definition should I change.

Answer 1

Using the Option Inspector:

In the Format menu choose Option Inspector, select Cell Options > New Cell Defaults and edit the value of the option DefaultNewInlineCellStyle.

In the screenshot below, I changed the value of this option from {} to "Subsection" using the drop-down menu. The first two cells on the left notebook show the inline cell styles before and after changing the value of the option in the Option Inspector.

Using SetOptions:

To change the for the new inline cells for the active notebook, use

 SetOptions[EvaluationNotebook[], DefaultNewInlineCellStyle -> "Section"]

Example cell containing an inline cell:

For the style change to apply to all new inline cells in the current front-end session, use

 SetOptions[$FrontEndSession, DefaultNewInlineCellStyle -> "Section"]

If you want to have the changes to persist across sessions, use

 SetOptions[$FrontEnd, DefaultNewInlineCellStyle -> "Section"]

Finally, to reset any of the changes, use

 SetOptions[xxx, DefaultNewInlineCellStyle -> Inherited]

where xxx is EvaluationNotebook[], or $FrontEndSession or $FrontEnd.

Setting your own custom styles:

 SetOptions[EvaluationNotebook[], 
 DefaultNewInlineCellStyle -> {FontFamily -> "SketchFlowPrint", FontSize -> 24}]

Answer 2

To do this via a StyleSheet add this to your stylesheet:

Cell[StyleData["InlineCell"],
 TextAlignment->Left,
 LanguageCategory->"Formula",
 ScriptLevel->1,
 StyleMenuListing->None,
 FontFamily->"Helvetica",
 FontSize->16]


Cell[StyleData["InlineCellEditing"],
 StyleMenuListing->None,
 Background->RGBColor[1,0,0]]

To create your stylesheet you could follow these steps if you prefer doing things programmatically:

Quickly editing the stylesheet and saving it

or if you prefer a more "standard" way of adding a stylesheet you could follow the steps outlined by @kguler in the comment below.