Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

The documentation for the function ToRadicals says:

♦ There are some cases in which expressions involving radicals can in principle be given, but ToRadicals cannot find them.

I'm concerned only with cases where the argument to ToRadicals is a single Root object with a single polynomial function with integer coefficients and no parameters, and an explicit root index.


Here is an example when Mathematica cannot find an expression in radicals:

ToRadicals[Root[-1 - #1^2 - #1^3 + #1^4 + #1^6 &, 2]]

But actually the expression exists: $$\frac1{\sqrt[3]{36}}\left(\frac3{\sqrt{\beta\phantom{.}}}+\frac\beta2\right),\ \text{where}\ \beta=\sqrt[3]{2\,\ \alpha}-8\sqrt[3]{\frac3\alpha\phantom{}},\ \alpha=9+\sqrt{849}.$$


Another example is

ToRadicals[Root[6 + 25 #1 - 25 #1^3 + 5 #1^5 &, 5]]

where the expression in radicals is $$\sqrt[5]{\frac{-3+4\sqrt{-1}}5}+\sqrt[5]{\frac{-3-4\sqrt{-1}}5}$$


What is the nature of this restriction? Is the problem known to be undecidable in general? Or is it extremely computationally expensive?

Can we write an implementation of ToRadicals that is able to find an expression in radicals in all cases when it is possible? Or, at least, in much more cases then the built-in ToRadicals does?

share|improve this question
1  
Requires computational Galois theory in general. It's computationally expensive and probably nowhere implemented in Mathematica. –  Daniel Lichtblau Oct 14 '13 at 19:24

2 Answers 2

rad = Root[-1 - #^2 - #^3 + #^4 + #^6 &, 2];
poly = rad[[1]][x]
PolynomialRemainder[poly, x^2 + a x + b, x]
a /. SolveAlways[% == 0, x];
Factor[poly, Extension -> %[[1]]];
x /. Solve[% == 0, x];
ans = Select[%, N[# == rad] &] // First // Simplify

-1 - x^2 - x^3 + x^4 + x^6

-1 + b- a b- a^2 b- a^4 b + b^2 + 3 a^2 b^2 - b^3 + (a - a^2 - a^3 - a^5 + b + 2 a b + 4 a^3 b - 3 a b^2) x

1/12 (8 3^(2/3) (2/(-9 + Sqrt[849]))^(1/3) - 2^(2/3) (3 (-9 + Sqrt[849]))^(1/3) + Sqrt[ 2 (24 + 96 3^(1/3) (2/(-9 + Sqrt[849]))^(2/3) + 2^(1/3) (3 (-9 + Sqrt[849]))^(2/3))])

share|improve this answer
    
This approach works on my original example, but fails to express Root[6 + 25 # - 25 #^3 + 5 #^5 &, 5] in radicals. But actually it is $\sqrt[5]{\frac{-3+4\sqrt{-1}}5}+\sqrt[5]{\frac{-3-4\sqrt{-1}}5}$. –  Vladimir Reshetnikov Oct 14 '13 at 20:38

We can solve your quintic by substituting $x = y + \frac{1}{y}$. This gives the equation $5y^5 + 6 + \frac{5}{y^5} = 0$, which is quadratic in $y^5$.

In[1]:= Module[{poly, y, sol},
   poly = 6 + 25x - 25x^3 + 5x^5;
   sol = y + 1/y /. Solve[0 == poly /. x -> y+1/y, y];
   Union[Select[sol, Chop[N[poly /. x -> #]] == 0&], SameTest -> (N[#1] == N[#2]&)]
]

Out[1]= {
   1/(-(3/5)-(4 I)/5)^(1/5)+(-(3/5)-(4 I)/5)^(1/5),
   (-1)^(4/5)/(-(3/5)-(4 I)/5)^(1/5)-(-1)^(1/5) (-(3/5)-(4 I)/5)^(1/5),
   -((-1)^(3/5)/(-(3/5)-(4 I)/5)^(1/5))+(-1)^(2/5) (-(3/5)-(4 I)/5)^(1/5),
   (-1)^(2/5)/(-(3/5)-(4 I)/5)^(1/5)-(-1)^(3/5) (-(3/5)-(4 I)/5)^(1/5),
   -((-5)^(1/5)/(-3-4 I)^(1/5))+(-1)^(4/5) (-(3/5)-(4 I)/5)^(1/5)
}

I got lucky here trying to sub $x = y + \frac{a}{y}$. Here's Mathematica code, written by Michael Trott, to solve any quintic solvable in radicals. It's old code, so some modifications will need to be made. It would be really cool if this was incorporated into ToRadicals!

http://library.wolfram.com/infocenter/Demos/158/

Unfortunately, I'm unable to get it to solve your quintic though!

Edit

I think ToRadicals is generally intended for cubics and quartics. Trying to find roots of simple quintics such as $(x+1)^5+2$ in terms of radicals doesn't even seem to work out.

In[2]:= Solve[3 + 5 x + 10 x^2 + 10 x^3 + 5 x^4 + x^5 == 0, x] // ToRadicals

Out[2]= {
   {x -> Root[3 + 5 #1 + 10 #1^2 + 10 #1^3 + 5 #1^4 + #1^5 &, 1]}, 
   {x -> Root[3 + 5 #1 + 10 #1^2 + 10 #1^3 + 5 #1^4 + #1^5 &, 2]},
   {x -> Root[3 + 5 #1 + 10 #1^2 + 10 #1^3 + 5 #1^4 + #1^5 &, 3]},
   {x -> Root[3 + 5 #1 + 10 #1^2 + 10 #1^3 + 5 #1^4 + #1^5 &, 4]},
   {x -> Root[3 + 5 #1 + 10 #1^2 + 10 #1^3 + 5 #1^4 + #1^5 &, 5]}
}
share|improve this answer

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.