Minimization problem

How could you find the smallest constant $c$ that satisfies

$$\frac{3^{3k}e\sqrt{3}}{\pi\sqrt{k}\;2^{3/2+2k}} \leq 2^{\;c\;k}$$

assuming $k\geq 1$ is an integer.

You can of course take logs of both sides and divide by $k$.
Can Mathematica then somehow minimize for $c$?

The code for the main term above is

(E/Sqrt[2Pi])/(x^(n x) (1 - x)^(n (1 - x)) Sqrt[ 2Pi n x (1 - x)])/. x -> 1/3 /. n->3k

-
Could you please post Mathematica code ? –  b.gatessucks Sep 21 '13 at 19:33
@b.gatessucks Done. –  felix Sep 21 '13 at 19:51

Going with your suggestion to take the Log of both sides we, after simplification, end up with:

(2 + k Log[729/16] + Log[3/(8 k π^2)])/(k Log[4]) <= c


Noticing that the lhs is strictly increasing in the domain of interest:

f[k_] := (2 + k Log[729/16] + Log[3/(8 k π^2)])/(k Log[4])

Reduce[ k >= 1 && f'[k] > 0, k]
(* k >= 1 *)


We can just take the limit as $k \rightarrow \infty$ to get the global suprema, which will also be the minima for c:

Limit[ f[k], k->Infinity]
(* Log[729/16]/Log[4] *)


For fixed k Minimize is able to find the minimal c when putting the inequality as a constraint:

cmin[k_Integer] := cmin[k] = Block[{c},
ArgMin[{ c, (3^(3 k) E Sqrt[3])/(π Sqrt[k] 2^(3/2 + 2 k)) <= 2^(c k)}, c]]

cmin[200]
(* (2 - 806 Log[2] + 1201 Log[3] - 2 Log[5] - 2 Log[π])/(400 Log[2]) *)

DiscretePlot[ cmin[k], {k, 1, 200}, Joined -> True, PlotRange -> All]


-
That is a nice solution. Thank you. –  felix Sep 21 '13 at 20:49

You can see than the lhs behaves like $(3^3/2^2)^k$. The rhs is $2^{ck}$. Therefore $$c = 3\log_23-2.$$

Also you can easily proof than the ratio lhs/rhs monotonically increases for $k\ge1$.

-

It can also be solved directly by setting the two sides equal:

sol = Solve[(3^(3 k) E Sqrt[3])/(π Sqrt[k] 2^(3/2 + 2 k)) == 2^(c k), c, Reals]


which gives an expression for c in terms of k as long as k > 0.

{{c -> ConditionalExpression[(2 - 3 Log[2] - 4 k Log[2] + Log[3] + 6 k Log[3] +
2 Log[1/(Sqrt[k] π)])/(2 k Log[2]), k > 0]}}


Set this equal to a function

    f[k_] := sol[[1, 1, 2, 1]]


and find the limit as k -> Infinity:

Limit[ f[k], k -> Infinity]


which is

   Log[27/4]/Log[2]

-
I am looking for a constant value of $c$ that holds for all integer $k \geq 1$. –  felix Sep 21 '13 at 20:47
Could you explain the code sol[[1, 1, 2, 1]] please ? That is new to me. –  felix Sep 21 '13 at 20:55
@felix If you evaluate sol then sol[[1]] then sol[[1,1]] then .... you'll see what's going on. relevant documentation –  ssch Sep 21 '13 at 20:58
This is picking out the function of k from the ConditionalExpression (it is the 1,1,2,1 element of the list defined by sol). It might be more straightforward to copy/paste the function into f[ ], but this was quicker to type. –  bill s Sep 21 '13 at 20:59