Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

The questions states:

Let

r[t_]:= {E^(-t), 3t^2, 4 Sin[t]}

Plot and compare r[t] and the integral of T[t], T[t] being the unit tangent vector.

share|improve this question

closed as off-topic by Daniel Lichtblau, belisarius, Artes, Kuba, m_goldberg Sep 19 '13 at 21:12

  • The question does not concern the technical computing software Mathematica by Wolfram Research. Please see the help center to find out about the topics that can be asked here.
If this question can be reworded to fit the rules in the help center, please edit the question.

    
Which question states that? Is it HW? –  belisarius Sep 19 '13 at 20:18
5  
This question appears to be off-topic because it is about math homework, not to do with the software Mathematica. –  Daniel Lichtblau Sep 19 '13 at 20:23
add comment

2 Answers 2

Can't have a question like this without Manipulate:

r[t_] := {Exp[-t], 3 t^2, 4 Sin[t]}
unitT[t_] := Normalize[r'[t]];
(* quicker to solve a DE once than calculate integral over and over *)
int = Module[{y, t},
  y /. First@NDSolve[{y[-Pi] == r[-Pi], y'[t] == unitT[t]}, y, {t, -Pi, Pi}]]

original = ParametricPlot3D[
   r[t], {t, -Pi, Pi},
   AxesLabel -> {x, y, z},
   BoxRatios -> 1,
   PlotRangePadding -> 5];
unitized = ParametricPlot3D[
   int[t], {t, -Pi, Pi},
   AxesLabel -> {x, y, z},
   BoxRatios -> 1,
   PlotRangePadding -> 1];

Manipulate[
 GraphicsRow[{
   Show[{
     original,
     Graphics3D[Arrow[{r[tt],r[tt] + r'[tt]}]]}]
   ,
   Show[
    unitized,
    Graphics3D[Arrow[{int[tt],int[tt] + unitT[tt]}]]
    ]}],
 {tt, -Pi, Pi}]

plots

share|improve this answer
add comment

I'm not really sure what you want, but since you should figure that out yourself anyway here is the most direct translation I can figure:

r[t_] := {E^(-t), 3 t^2, 4 Sin[t]}

Block[{t},
  f[t_] = Integrate[r[t], t]
];

ParametricPlot3D[{r[t], f[t]}, {t, 0, 10}, BoxRatios -> 1]
share|improve this answer
add comment

Not the answer you're looking for? Browse other questions tagged or ask your own question.