Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

There are several answers where Mathematica used mesh points to show graphically where curve intersections exist.

For example: Marking points of intersection between two curves or Is there a better way to get the eight points of intersection?

Is there a way to include the actual point values (maybe they are simply labeled as a, b, c ...) and then the actual value is displayed on the right of the graphic?

Here is the specific example I am working.

Plot[{Cos[x],(1/2)^x},{x,-1,11},
 PlotPoints->84,
 MaxRecursion->9,
 MeshFunctions->{Cos[#1]-(1/2)^#1&},
 Mesh->{{0}},
 MeshStyle->Directive[Red,PointSize[Large]]]
share|improve this question
1  
You can put Graphics[Text[#, #] & /@ coords] to the Show or just Text part to the Epilog. –  Kuba Sep 11 '13 at 6:09
1  
@Kuba ... and with small offset on the coordinate part of Text, it's positioned next to the point itself, not on top of it. –  kirma Sep 11 '13 at 6:41
1  
lines meet at solutions of two lines equations..may be you want to find solutions first and them use Text as suggested to get only relevant info. –  Rorschach Sep 11 '13 at 6:55

2 Answers 2

up vote 9 down vote accepted
opts = {ImageSize -> 500, PlotRange -> {{-5, 15}, All}, PlotPoints -> 84,
        MaxRecursion -> 9, MeshFunctions -> {Cos[#1] - (1/2)^#1 &}, Mesh -> {{0}}, 
        MeshStyle -> {Directive[Red, PointSize[Large]]}};

You may be interested in the fact that Mesh solution is good for visulatisation purposes but it seems that coordinates given with this method are only approximation.

Also there are double points, one for each curve and each aproximation is independent what may result in different coordinates.

Taking your example let's label those points:

(Plot[{Cos[x], (1/2)^x}, {x, -1, 11}, Evaluate@opts] // Normal
) /. Point[x_] :> ({Point@x,
                    Text[Style[NumberForm[#, {Infinity, 2}], Bold, Black, 15] &@x
                         , x + {0, .5 - RandomReal[]/2}]})

It basically replaces points with points + labels. Labels are with random offset so you can see what I was reffering to. Normal is in order to get rid of the GraphicsComplex. enter image description here

As you can see, the mesh point near $y$ axis has different coordinates :)


Edit So at the end I would use NSolve based solution like in the first link you've provided:

After all I forgot you asked for the legend next to the plot :)

points = {x, Cos[x]} /. NSolve[Cos[x] == (1/2)^x && -1 < x < 11, x];
names = FromCharacterCode /@ (Range[Length@points]+96)
{"a", "b", "c", "d", "e"}
 Row[{
      Plot[{Cos[x], (1/2)^x}, {x, -1, 11}, Evaluate@opts, 
          Epilog -> (Text[Style[#, 20], #2 + {0, .2}] & @@@ Transpose[{names, points}])
          ]
      ,
      Grid@MapThread[List, {names, points}]
    }]

enter image description here

share|improve this answer

Perhaps ugly but may achieve what you want:

p = Plot[{Cos[x], (1/2)^x}, {x, -1, 11}, PlotPoints -> 84, 
  MaxRecursion -> 9, MeshFunctions -> {Cos[#1] - (1/2)^#1 &}, 
  Mesh -> {{0}}, MeshStyle -> Directive[Red, PointSize[Large]], 
  ImageSize -> 300]

Extract intersection points (which as described are approximates with duplicates):

intp = Extract[p[[1, 1]], List /@ p[[1, 2, 2, 1, 2, 1]]]

"Clean" and sort (by removing "same" x value) and create labels:

sorted = Chop[#, 10^(-8)] & /@ 
  SortBy[DeleteDuplicates[intp, 
    Chop[#1[[1]] - #2[[1]], 10^(-4)] == 0 &], #[[1]] &]
labels = FromCharacterCode /@ (96 + Range[Length[sorted]])

Display:

Row[{
  Show[p, 
   Graphics[
    MapThread[
     Text[Style[#1, 16], #2 + {0.1, 0.2}] &, {labels, sorted}]]],
  Grid[Transpose[{labels, sorted}], Frame -> True]
  }]

yields:

enter image description here

share|improve this answer
    
I'm not sure if the way that you are getting intp is safe enough to be used always, maybe you can use something like: Cases[p, GraphicsComplex[x_, ___] :> Part[x, First@Cases[p, Point[z_] :> z, \[Infinity]]], \[Infinity]] –  Kuba Sep 11 '13 at 8:30
    
@Kuba Thank you, I agree entirely that this is not general and just an interrogation and dissection of the GraphicsComplex. I just wished to show that you can access the points. I regard this as ugly but hoped that comments such as yours would arise. Thank you for the more general method...I have learned something. –  ubpdqn Sep 11 '13 at 8:39
    
I'm glad you find it useful. :) –  Kuba Sep 11 '13 at 8:43

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.