Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

Generally many programs have a menu item to raise/lower current font size. This is much more convenient than trying to root around in in internal mathematica options.

I need to change ALL default fonts not just particular ones. For instance the help system font is itself too small on my laptop. I hope there is a way to do what I want without having to know about a lot of different settings. I am not interested in how uber flexible internal settings are but in having a product that is comfortably readable and useable without a lot of fooling around.

share|improve this question
1  
Have you tried increasing the magnification (Window -> Magnification)? –  rm -rf Sep 8 '13 at 21:54
    
@rm-rf There were couple of posts here that working on magnification different than 100% causes errors. I've faced it too. –  Kuba Sep 8 '13 at 22:44
    
User, I hope that you will find at least one answer to one of the three questions now linked in the "already has an answer" header to satisfy. If you do not please let me know in what way they all fail you. –  Mr.Wizard Sep 10 '13 at 10:42
add comment

marked as duplicate by halirutan, Kuba, Michael E2, István Zachar, Mr.Wizard Sep 10 '13 at 10:40

This question has been asked before and already has an answer. If those answers do not fully address your question, please ask a new question.

1 Answer

For various reasons, mostly connected to poor eyesight, I frequently want to change window size and magnification. To make this convenient, I have built a palette that has buttons to set these frequently used options. It might help you too. Here is the code ...

With[{setMag = (CurrentValue[InputNotebook[], Magnification] = #) &},
  CreatePalette[
    Framed@Column[{
      Style[" Magnification", Bold, 11],
      Button["100%", setMag[1.], Appearance -> "Palette", ImageSize -> 120],
      Button["125%", setMag[1.25], Appearance -> "Palette"],
      Button["150%", setMag[1.5], Appearance -> "Palette"],
      Style[" Ruler", Bold, 11],
      Button["Show",
        With[{wtb = CurrentValue[InputNotebook[], WindowToolbars]}, 
          CurrentValue[InputNotebook[], WindowToolbars] = 
            DeleteDuplicates@Flatten[{wtb, "RulerBar"}]],
        Appearance -> "Palette"],
      Button["Hide",
        With[{wtb = CurrentValue[InputNotebook[], WindowToolbars]},
        Switch[wtb,
         "RulerBar", CurrentValue[InputNotebook[], WindowToolbars] = {},
         _List, CurrentValue[InputNotebook[], WindowToolbars] = 
           DeleteCases[wtb, "RulerBar"]]],
        Appearance -> "Palette"],
      Style[" Size", Bold, 11],
      Button["880 \[Times] 1000", 
        CurrentValue[InputNotebook[], WindowSize] = {880, 1000}, 
        Appearance -> "Palette"],
      Button["725 \[Times] 755", 
        CurrentValue[InputNotebook[], WindowSize] = {725, 755}, 
        Appearance -> "Palette"]}],
    WindowTitle -> "Window Options"]];

... and here is how it looks when deployed.

palette.png

To install the palette, evaluate the code, select Install Palettes... from the Palettes menu, and complete the ensuing dialog box. After installation the new palette will appear in the Palettes menu.

Note: You will probably get an alert asking to save the palette as a notebook, even after installation. Just ignore it -- the installation process saves the palette to the correct directory.

share|improve this answer
add comment

Not the answer you're looking for? Browse other questions tagged or ask your own question.