Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

I have a Mathematica script to help me copy images from PDFs and then make the (presumably white or nearly white) background transparent. Typically, I am looking at the PDF in Adobe Acrobat and I use the snapshot tool to copy the image to Microsoft Window's clipboard. Then I paste the image into mathematica and assign it the name q. Where I typed {IMAGE} below is where I paste the image into the code:

q = {IMAGE};
p = ColorNegate[Binarize[ImageApply[Min, q], 0.99]];
s = SetAlphaChannel[q, p];
Export["img.png", s];

I run the code and I get a PNG with a transparent background and then I can insert the png with the transparent background into OneNote.

The point of doing this is images with a transparent background are easier to arrange since the don't obscure the other texts. This makes it a snap to place graphs and equations in my notes.

I would like to make this even easier by enhancing my script. This is why I am asking for help. My goals are:

  1. Is there some Mathematica command I can use to copy the image from the clipboard automatically without having to manually paste it.

  2. Is there a way to get Mathematica to place the image back into the clipboard with a transparent background, thus cutting out the step of using a file.

What I have found is if I use a command like CopyToClipboard[s], it doesn't work.

  1. Are there any other enhancements that would make the whole process more automated?

(A side note: it's been a while since I wrote this code, but if I remember correctly, I convert the image to black and white, figure out the background then use the pixels that were designated as background to figure out which pixels to set as transparent in the original image.)

share|improve this question
2  
See this question for how to make a white background transparent. –  rm -rf Mar 16 '12 at 13:49
    
@R.M:Thanks for the link. My main interest is copying the image from the clipboard and copying back the modified image to the clipboard. The part of my code that makes the background transparent actually works quite well for my needs. Thanks. –  Henry B Mar 16 '12 at 13:55
    
@HenryB I think you should post a separate question about the clipboard. That is unrelated to image processing. –  Szabolcs Mar 16 '12 at 14:05
1  
@HenryB I suggest you change the title and the details of your question if you're not interested in the transparent part –  rm -rf Mar 16 '12 at 14:08
    
Thanks for the advice. –  Henry B Mar 16 '12 at 15:11
show 3 more comments

1 Answer 1

up vote 11 down vote accepted

Here are two functions that'll do what you need.

putClipboardImage[img_Image] := Module[{nb},
  nb = CreateDocument[{}, Visible -> False, WindowSelected -> False];
  NotebookWrite[nb, 
   Cell[BoxData@ToBoxes@Image[img, Magnification -> 1]]];
  SelectionMove[nb, All, CellContents];
  FrontEndTokenExecute[nb, "CopySpecial", "MGF"];
  NotebookClose[nb]
  ]

getClipboardImage[] := Module[{tag},
  Catch[NotebookGet@ClipboardNotebook[] /. 
    r_RasterBox :> 
     Block[{}, 
      Throw[Image[First[r], "Byte", ColorSpace -> "RGB"], tag] /; 
       True];
   $Failed, tag]
  ]

Warning: if the image is very small, this method will pad it with some wide pixels. It is copying the cell contents, not the image itself. If the image is small than the cell height, it'll get padded.

Copying

The reason the image can't be pasted to every program when using CopyToClipboard is that it is placed onto the clipboard as a metafile (as well as a Mathematica expression), but not as a bitmap.

My function works by writing the image into a new hidden notebook, then invoking the Edit -> Copy As -> Bitmap command programmatically, to ensure that the image is placed on the clipboard as a bitmap. This works on Windows, but on OS X it's probably necessary to change MGF to something else, as the same command is not available (try PDF). On Linux this functionality is simply not available.

Pasting

Pasting works by accessing the special object ClipboardNotebook[] and reading its contents. The unusual looking ReplaceAll - Throw - Catch construct is just a performance optimization to avoid unpacking the array representing the image data.

I used the same techniques in the image uploader palette.

share|improve this answer
    
Thanks for the excellent answer. One problem is the transparent background. It seems that when I paste the image back to the clipboard using your code, it has a non-transparent background again. Should I perhaps ask a separate question on this issue? –  Henry B Mar 17 '12 at 12:41
    
At the end of my code, I export the img to a file ( Export["img.png", s]; ). Maybe a reference to the file can somehow be stored in the clipboard. Not sure how this works ie. if a reference to a file is stored in the clipboard and that's why it works to copy the img from my desktop and paste the file into OneNote. –  Henry B Mar 17 '12 at 12:50
    
@Henry To my knowledge, it's not possible to store an image with alpha channel on the Windows clipboard---at least in the standard format. Applications-specific formats are fine but can't be pasted anywhere except the application that produced them (as you discovered). About the reference, I'm not sure how that would work, or how to do that. I don't know much about the clipboard either. –  Szabolcs Mar 17 '12 at 17:25
    
@Henry After opening up Dito ditto-cp.sourceforge.net in windows it appears file references are stored using CF_DROP. On a side it appears transperency was discussed over at stackoverflow.com/questions/15689541/… and they managed to create a semi working solution. –  Liam William May 27 '13 at 20:22
1  
@HenryB I wrote up some code that copies mathematica PNGs to the clipboard over here mathematica.stackexchange.com/questions/26105/… –  Liam William Jul 7 '13 at 4:01
show 1 more comment

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.