Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

I want to adjust some code that I found on this Wolfram Demonstration: http://demonstrations.wolfram.com/WaterRipplesPassingThroughASlit/

Basically it shows a wave passing through a single slit. I want to change the code so that there is no longer any slit, so the wave just bounces off the walls. It's that bit I'm having trouble with. I'll put the code I have now then explain what I think it's doing and what I've tried:

Manipulate[
 With[{ripple = iter[tf]},

  Show[ListPlot3D[ripple, Mesh -> False, PlotRange -> {-1, 1}, 
    ImageSize -> 450, ColorFunction -> "PearlColors", Axes -> False]]],
 {{tf, .45, Style["t", Italic]}, 0.05, 1., 0.001, ImageSize -> Tiny},
 ControlPlacement -> Left,
 SynchronousInitialization -> False,
 SynchronousUpdating -> False,
 Initialization :> (
   n = 64; dx = 1.0/(n - 1.);
   Courant = 1/Sqrt[2];
   dt = (Courant dx)/c; c = 1.; 
   iter = Compile[{{tf, _Real}}, 
     Module[{z1 = ConstantArray[0., {64, 64}], 
       z2 = ConstantArray[0., {64, 64}]}, 
      Do[{z1, z2} = {z2, z1}; z1[[32, 16]] = Sin[16. \[Pi] t]; 
       Do[If[0.45 < i/n < 0.55 || ! 0.48 < j/n < 0.52, 
         z2[[i, j]] = 
          1/(1. + 5. dt) (Courant^2 (z1[[i - 1, j]] + z1[[i + 1, j]] +
                 z1[[i, j - 1]] + z1[[i, j + 1]])) - z2[[i, j]]], {i, 
         2, 63}, {j, 2, 63}], {t, 0., tf, dt}]; z1]];)]

I don't think anything before 'Initialization' needs to be changed. The second half sets up two 64X64 grids z1 and z2. They get updated by the Do command. The part that seems to be directly about the slit is

       Do[If[0.45 < i/n < 0.55 || ! 0.48 < j/n < 0.52, 
         z2[[i, j]] = 
          1/(1. + 5. dt) (Courant^2 (z1[[i - 1, j]] + z1[[i + 1, j]] +
                 z1[[i, j - 1]] + z1[[i, j + 1]])) - z2[[i, j]]], {i, 
         2, 63}, {j, 2, 63}], {t, 0., tf, dt}]

Because it is telling the program to do something if the grid in question is where the slit should be. The issue is that I can't just delete that part, because then the wave doesn't evolve over time! It's like the instructions for how the other parts of the grid should act are also in that line, but I don't understand it.

Any hints at all would be so useful, I've been stuck for a day!

share|improve this question
1  
Just leave Do[ z2[[i, j]] = ...] but delete this condition. –  Kuba Aug 18 '13 at 10:35

1 Answer 1

up vote 2 down vote accepted

As I wrote earlier you just have to delete the condition. To explain a little bit:

n = 64;
arr = Array[Boole[0.45 < #/n < 0.55 || ! 0.48 < #2/n < 0.52] &, {64, 64}];

ArrayPlot[arr, ImageSize -> 300]

enter image description here

Black area is the area where condition inside If allows the wave to propagate.

So if the wave is comming from the left and face the "wall" it just stops. And the part that manage to get through the slit can propagate again in all directions as there is all in Black.

By removing this condidtion we are leaving whole area Black.

enter image description here

share|improve this answer

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.