Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

Although Mathematica has some nice plotting capabilities, there are some things which are annoying me:

I like to export a Graphics oder Plot to PDF for use in $\LaTeX$. I like to a have an ImageSize of the PDF file, which corresponds to the image size in my document (e.g. 6 cm). I don't like to scale my image in $\LaTeX$.

When exporting to PDF the PlotRangeClipping does not work as expected (especially when having a small ImageSize):

cm=72/2.54;
p1 = Graphics[{EdgeForm[{Red, Thickness[.1]}], FaceForm[], Disk[]},
  Frame -> True,
  PlotRange -> {{0, 1}, {0, 1}},
  PlotRangeClipping -> True,
  ImageSize -> 6 cm]
Export["p1.pdf", p1]

p2 = Graphics[{EdgeForm[{Red, Thickness[.1]}], FaceForm[], Disk[]},
  Frame -> True,
  PlotRange -> {{0, 1}, {0, 1}},
  PlotRangeClipping -> True,
  ImageSize -> 26 cm]
Export["p2.pdf", p2]

While the PlotRangeClipping for in the second generated file (p2.pdf) is more or less okay (not perfect),

p2.pdf magnified

there are serious problems in p1.pdf:

p1.pdf magnified

Is this a bug? Is there a way to have an acceptable PlotRangePadding with a small ImageSize?

share|improve this question

2 Answers 2

up vote 5 down vote accepted

The reason why this overhang appears is that the Thickness of the line marking the edge of the Disk is not counted as something that needs to be clipped (although it should). The line itself (the center of the thick red line) is clipped correctly.

But of course the result looks very clumsy, and it can only be eliminated if the line thickness is made as small as the thickness of the Frame. So in order to get a prettier result, you have to mask the overhanging line thickness manually. Here is how you could do it:

p1 = Graphics[{EdgeForm[{Red, Thickness[.1]}], FaceForm[], Disk[]}, 
   Frame -> True, PlotRange -> {{0, 1}, {0, 1}}];

Show[p1, With[{d = .2},
  Graphics[
   {White, FilledCurve[
     {
      {Line[{{-d, -d}, {-d, 1 + d}, {1 + d, 1 + d}, {1 + d, -d}}]},
      {Line[{{0, 0}, {0, 1}, {1, 1}, {1, 0}}]}
      }
     ]}
   ]
  ], ImageSize -> 6 cm]

The FilledCurve is a square with a hole in it, like a picture frame with a with border of thickness d = .2 in plot units.

The exported PDF looks like this:

exported pdf

Edit to make it work independently of PlotRange

To make the cropping frame resize automatically with the PlotRange, I went back to the question Changing the background color of a framed plot and saw that there was an answer by István Zachar that also uses FilledCurve and applies Scaled and ImageScaled to the rectangle borders. Using that approach directly still lets some of the red arc peek through in the notebook display, so I combined that approach with my above choice of an extra width d, and that should work for arbitrary PlotRange:

Show[p1, With[{d = .2}, 
  Graphics[{White, 
    FilledCurve[{{Line[
        ImageScaled /@ {{-d, -d}, {-d, 1 + d}, {1 + d, 
           1 + d}, {1 + d, -d}}]}, {Line[
        Scaled /@ {{0, 0}, {0, 1}, {1, 1}, {1, 0}}]}}]}]], 
 ImageSize -> 6 cm]

For more games that you can play with FilledCurve, see e.g. Filling a polygon with a pattern of insets.

share|improve this answer
    
Also nice! Is there a way to make this procedure independent of the PlotRange? –  grbl Aug 5 '13 at 17:15
    
Yes, I added an update to make that approach work for any PlotRange. –  Jens Aug 5 '13 at 17:47
    
Looking at the output postscript (EPS which does the same thing) mathematic sends the full curve and lets the postcript engine do the clippimng. I suspect the core issue is that mathematica is (unnecessarily) rounding the clip path values to integers. –  george2079 Aug 5 '13 at 19:50
    
@george2079 That's interesting, I didn't look at the details. Can I add this to my answer? –  Jens Aug 5 '13 at 20:31
1  
Yes! Now it is working solution. Thx. (Although I hope that Wolfram will fix these kind of issues with plotting one day!) –  grbl Aug 6 '13 at 14:48

Here are the steps to the obtain the PDF's files you want without the problems you showed. I am going by the assumption that there is no simple Plot option we are overlooking here, so this solution uses Inskscape to get the pdf file without the clipping you show.

1) Download the install free software Inskscape

2) Export the images you want to svg and not to pdf

SetDirectory[NotebookDirectory[]]
Export["p2.svg", p2]
Export["p1.svg", p1]

3) Open Inskscape and read p1.svg , then do save as and select PDF and make sure to use the "export area is drawing option"

Mathematica graphics

4) Now open the p1.pdf, and it will be OK

Mathematica graphics

Do the same for p2.pdf :

Mathematica graphics

I've put the pdf files p1.pdf and p2.pdf here for you to check.

share|improve this answer
    
Nice! I didn't try svg export yet, but it looks promising! This can even be automated! –  grbl Aug 4 '13 at 15:40
    
Look at the lower left corner of p1.pdf. The problem is still there I think... (I'd managed to get this far with ImageSize -> {w,h}... –  cormullion Aug 4 '13 at 16:09

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.