Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

I'm dealing with strings in Mathematica and I would love to handle their stylling in the most cenvenient way.

Without loss of generality, let's assume I want to make some parts of string Bold.

Example of desired output:

to be or not to be

I know I can achieve that by for example:

StringForm["to `` or `` to be", ##] & @@ (Style[#, Bold]& /@ {"be", "not"}) 

but I want single function bold and some kind of markers (here #):

bold @ "to #be# or #not# to be"

to be or not to be


It is my approach:

bold = Module[{x}, 
              With[{patt = "#" ~~ x : Except["#"] .. ~~ "#"},
       StringForm @@ ({
                      StringReplace[#, patt :> "``"],
                      Sequence @@ StringCases[#, patt :> Style[x, Bold]]
                      })]
             ] &

and I have couple of questions about it:

  • do you feel that # is not the best choice too? :)
  • is this: {patt = "#"~~...} a proper way of storing patterns?
  • maybe some other ideas?

I like this way but I'm not sure if it is bulletproof. It is quite handy because StringCases etc do not look for overlaps by default.

Notice that mixed-style-string-form tends to produce some kind of error If you want to edit that cell. This is also what I to want to ask about:

INTERNAL SELF-TEST ERROR: MathEditCells2|c|1384
Click here to find out if this problem is known, and to help improve
Mathematica by reporting it to Wolfram Research
share|improve this question
    
Is the question about style markers in strings or on the choice of # or about patterns? As for #, why invent new styles when it is easier to use something commonly used, such as **bold** in markdown? –  rm -rf Jul 28 '13 at 18:01
    
@rm-rf it is a question about implementation/creating such function in Mathematica so one do not need to use Row or StringForm each time. If there are markers in MMA like "\ n " then it is a question about them. –  Kuba Jul 28 '13 at 18:05

1 Answer 1

up vote 7 down vote accepted

You can use # or any other marker for your personal use, but for general purposes, I prefer sticking to the Markdown scheme that we're all familiar with, and is used in several other places. With the styleMarkdown function defined later in this answer, we can do something like this:

styleMarkdown["The **quick** brown fox *jumps* over the ***lazy*** dog."]

Here's the code for the above function:

ClearAll@styleMarkdown
styleMarkdown[str_String] := Module[{style, applyRules},
    style[s_String, {weight_ : Plain, slant_ : Plain}] := StringJoin[
        "\!\(\*StyleBox[\"", s, "\", FontWeight -> ", ToString@weight,
        ", FontSlant -> " , ToString@slant, "]\)"];

    applyRules[s_String, rules_] := 
        StringReplace[s, # ~~ Shortest@x__ ~~ # :> style[x, #2] & @@@ rules];

    applyRules[str, {"***" -> {Bold, Italic}, "**" -> {Bold}, "*" -> {Plain, Italic}}]
]

The function only handles bold, italic and bolditalic, but you can extend it to other styles, if you want. The limitations in markdown also apply here. For example, with ****foo****, is it to be interpreted as (markers in [] and styled text in <>) *[***<foo>***]* or [***<*foo>***]* or *[***<foo*>***], and so on.

share|improve this answer
    
Thank you, this seems to be more stable. –  Kuba Jul 28 '13 at 19:50

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.