Mathematica Stack Exchange is a question and answer site for users of Mathematica. Join them; it only takes a minute:

Sign up
Here's how it works:
  1. Anybody can ask a question
  2. Anybody can answer
  3. The best answers are voted up and rise to the top

Is there any way to force Mathematica to come up with the closed form to

Sum[1/(i^18 (i^2 + j^2)), {i, 1, Infinity}, {j, 1, Infinity}]

or

Sum[1/(i^4 (i^2 + j^2)), {i, 1, Infinity}, {j, 1, Infinity}]

? The former series definitely has a closed form, whereas the 2nd one might have or not.

share|improve this question
    
I conjecture that all double series having at denominator the form $i^{4k+2} (i^2 + j^2)$ could be expressed in terms of $\pi$ and zeta function. – A_math_ninja Jul 27 '13 at 7:37
up vote 7 down vote accepted

I like to use a little trick.

Apart[1/(i^18 (i^2 + j^2)), i]
(* 1/(i^2 j^18) - 1/(i^4 j^16) + 1/(i^6 j^14) - 1/(i^8 j^12) + 
   1/(i^10 j^10) - 1/(i^12 j^8) + 1/(i^14 j^6) - 1/(i^16 j^4) + 1/(i^18 j^2) 
   - 1/(j^18 (i^2 + j^2)) *)

All the terms except the last one are easy. When summed upon, the last term equals our original series due to symmetry, therefore we can just sum the easy bits and then divide by 2.

aux = Sum[ 1/(i^2 j^18) - 1/(i^4 j^16) + 1/(i^6 j^14) - 1/(i^8 j^12) + 
           1/(i^10 j^10) - 1/(i^12 j^8) + 1/(i^14 j^6) - 1/(i^16 j^4) + 
           1/(i^18 j^2), {i, 1, Infinity}] ;

result = 1/2 Sum[aux, {j, 1, Infinity}]
(* (584887 \[Pi]^20)/4764136114237500 *)

Check :

N[result]
(* 1.07668 *)

NSum[1/(i^18 (i^2 + j^2)), {i, 1, Infinity}, {j, 1, Infinity}]
(* 1.07668 *)

I think one can use the same way for the other sum.

share|improve this answer
1  
Very nice and useful this trick. (+1) – A_math_ninja Jul 27 '13 at 8:01
    
The other sum doesn't work this way. – A_math_ninja Jul 27 '13 at 8:06

First problem

Break the sum into 2 parts:

Clear[m]; 
s1 = Sum[1/(i^18*(i^2 + j^2)), {j, 1, m}]; 
s1 = Limit[s1, m -> Infinity]

Out[49]= (-1 + i*Pi*Coth[i*Pi])/(2*i^20)

Now the second part, Mathematica can't sum. i.e s2 = Sum[s1, {i, 1, m}], but we can numerically look at it for larger and larger m values...

data = Table[{m, NSum[s1, {i, 1, m}]}, {m, 1, 100}];
ListPlot[data, Joined -> True, Mesh -> All, PlotRange -> All]

Mathematica graphics

data[[-1, 2]]
Out[53]= 1.07668

Second problem

 Clear[m]
 s1 = Sum[1/(i^4*(i^2 + j^2)), {j, 1, m}]; 
 s1 = Limit[s1, m -> Infinity]

 Out[28]= (-1 + i*Pi*Coth[i*Pi])/(2*i^6)

again, s2 = Sum[s1, {i, 1, Infinity}] does not sum. So try numerical

data = Table[{m, NSum[s1, {i, 1, m}]}, {m, 1, 100}];
ListPlot[data, Joined -> True, Mesh -> All, PlotRange -> All]

Mathematica graphics

 data[[-1, 2]]
 Out[46]= 1.12601
share|improve this answer
    
Thanks for answer. (+1) – A_math_ninja Jul 27 '13 at 8:01

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.