# How do I solve $1 - (1 - (A x)^2)^\frac{3}{2} - B(1 - \cos(x))= 0$?

Consider the equation

$$1 - (1 - (A x)^2)^\frac{3}{2} - B(1 - \cos(x)) = 0$$

where $A,B \in \mathbb{R}$ are constants.

What is the analytic solution?

-
There isn't any in most of such cases. It is transcendental equation. You need NSolve. –  Kuba Jul 18 '13 at 7:58
Manipulate A and B shows how sensitive the equation is. I'm afraid that an analytic solution is compromised.. –  Öskå Jul 18 '13 at 8:18
Since you are asking for the analytical solution to the equation is and not how to use Mathematica to solve it, I think the question doesn't belong here. –  Svend Tveskæg Dec 16 '13 at 1:22
Trancedental equations generally don't have an analytic solution. –  Sjoerd C. de Vries Dec 16 '13 at 6:39

In general, one cannot get explicit analytic solutions of trancendental equations in terms of radicals. This is also the case of univariate higher order polynomial equations. On the other hand since Mathematica 7 we can find exact solutions (in terms of Root objects) of a wide range of (univariate) trancendental equations, for more detailed discussion of these issues see e.g. How do I work with Root objects?.

To get an insight in the problem try to compare different series expansions of the underlying function around 0, Pi/4 and Pi/2 respectively, e.g.

Column[ Series[1 - (1 - (A x)^2)^(3/2) - B (1 - Cos[x]), {x, Sequence @@ #}]& /@ {
{0, 6},
{Pi/4, 4},
{Pi/2, 4}},   Frame -> All] // TraditionalForm


Even though the function is analytic, basically one cannot find close-form formulae of its roots. On the other hand there are mathematical theorems which precisely say when we could expect existence of an inverse function, see e.g. the implicit function theorem.

Since we expect certain kind of periodicity in x (because of Cos[x] term) we'll need to restrict the variable x to some bounded region in the complex plane. There is only one obvious solution for any a and b in terms of algebraic numbers x == 0. Working on the symbolic level with a and b neither Solve nor Reduce could find all solutions since the system wasn't able to decide how many solutions there were (in the whole plane we can expect infinitely many). In general we have to choose values of a and b as well as two complex numbers denoting a rectangle in the complex plane where we want to find all solutions.

sol[a_, b_, {c_, d_}] := Solve[ 1 - (1 - a^2 x^2)^(3/2) - b (1 - Cos[x]) == 0  &&
Re[c] < Re[x] < Re[d] &&
Im[c] < Im[x] < Im[d],     x]// Quiet


Let's find solutions for a == 1 and b == 2 and -10 < Re[x] < 10 and -10 < Im[x] < 10:

sol[1, 2, {-10 - 10 I, 10 + 10 I}]

{{x -> 0}, {x -> 0},
{x -> Root[{-1 + 2 Cos[#1] - Sqrt[1 - #1^2] + #1^2 Sqrt[1 - #1^2] &,
-8.919028748106532016537600495313203216599120982717
-7.337134108993067206908899611176545810648199786148 I}]},
{x -> Root[{-1 + 2 Cos[#1] - Sqrt[1 - #1^2] + #1^2 Sqrt[1 - #1^2] &,
-8.919028748106532016537600495313203216599120982717
+ 7.337134108993067206908899611176545810648199786148 I}]},
{x -> Root[{-1 + 2 Cos[#1] - Sqrt[1 - #1^2] + #1^2 Sqrt[1 - #1^2] &,
0.*10^-49 - 4.745288110568659108440764233893256927171177295653 I}]},
{x -> Root[{-1 + 2 Cos[#1] - Sqrt[1 - #1^2] + #1^2 Sqrt[1 - #1^2] &,
0.*10^-49 + 4.745288110568659108440764233893256927171177295653 I}]},
{x -> Root[{-1 + 2 Cos[#1] - Sqrt[1 - #1^2] + #1^2 Sqrt[1 - #1^2] &,
8.919028748106532016537600495313203216599120982717
- 7.337134108993067206908899611176545810648199786148 I}]},
{x -> Root[{-1 + 2 Cos[#1] - Sqrt[1 - #1^2] + #1^2 Sqrt[1 - #1^2] &,
8.919028748106532016537600495313203216599120982717
+ 7.337134108993067206908899611176545810648199786148 I}]}}


For deeper understanding of the solution space it is usually a good idea to visualize the geometry of the complex function with its roots therein. First we find all solutions in the Rectangle[{-30, -30}, {30, 30}] and mark them with the red color.

pts = {Re @ #, Im @ #}& /@ (x /. sol[1, 2, {-30 - 30 I, 30 + 30 I}]);


there are

Length @ DeleteDuplicates @ pts

19


of them, while in the rectangle denoted with the lighter color Rectangle[{-20, -10}, {20, 10}] we have

Length @ DeleteDuplicates @ sol[1, 2, {-20 - 10 I, 20 + 10 I}] // Quiet

11


Here we provide a graphics with appropriate solutions:

GraphicsColumn[
Table[ ContourPlot[ f[1 - (1 - 1^2 (x + I y)^2)^(3/2) - 2 (1 - Cos[(x + I y)])],
{x, -30, 30}, {y, -15, 15},
AspectRatio -> Automatic, ColorFunction -> "DeepSeaColors", Epilog ->
{{Directive[Opacity[0.25], Cyan], Rectangle[{-20, -10}, {20, 10}]},
{Red, PointSize[0.01], Point[pts]}},  Contours -> 11],
{f, {Re, Im}}]]


-