Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

I typed

StreamPlot[{y, x-x^3-0.3y+0.5Cos[1.25t]}, {x, -2.5, 2.5}, {y, -2.5, 2.5}]

but all I got was a blank plot. What did I do wrong and can I fix it?

share|improve this question
    
But I don't want to specify any value for $t$. Is there any other function I should use? Anything in 3D? –  Student Jul 15 '13 at 14:44

3 Answers 3

up vote 7 down vote accepted

If you don't want to specify t there is e.g. ListAnimate (or Animate etc.)

ListAnimate[ 
    Table[ StreamPlot[{y, x - x^3 - 0.3 y + 0.5 Cos[1.25 t]}, 
                               {x, -2.5, 2.5}, {y, -2.5, 2.5}], {t, 0.1, 2, 0.05}]
           ]

enter image description here

share|improve this answer
    
it looks like that would make an interesting bifurcation plot ... –  rcollyer Jul 15 '13 at 16:32

This may be more like what you asked for in a comment, but as you can see, Artes's animation might be a better visualization.

Show[
 Table[
  Graphics3D[
   First@(StreamPlot[{y, x - x^3 - 0.3 y + 0.5 Cos[1.25 t]},
            {x, -2.5, 2.5}, {y, -2.5, 2.5}, 
            StreamStyle -> Hue[Rescale[t, {-1.2, 1.2}]]] /. 
          Arrow[pts_] :> 
            Arrow[Transpose[Transpose@pts~Append~ConstantArray[t, Length@pts]]])],
  {t, -1, 1, 0.5}],
 Axes -> True, BoxRatios -> {1, 1, 1}]

Mathematica graphics

See also some of the answers to this question for more on combining 2D plots into 3D graphics.

share|improve this answer

Or you could use the beautiful LineIntegralConvolutionPlot function - Documentation center link: Here

Manipulate[
LineIntegralConvolutionPlot[{y, 
x - x^3 - 0.3 y + 0.5 Cos[1.25 t]}, {x, -2.5, 2.5}, {y, -2.5, 2.5},
ColorFunction -> ColorData["Rose"], StreamPoints -> 10, 
StreamStyle -> White], {t, -2.5, 2.5}]

LineIntegralConvolutionPlot

share|improve this answer
    
Blagodarq ti, Nikola. –  Student Jul 16 '13 at 6:09
    
Nyama zashto :) –  Sektor Jul 16 '13 at 10:41

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.