Incorporating an additional graphics element when using Animate and ParametricPlot3D

Question

I'm trying to animate some curves that wrap around a cylinder. OK so far:

Animate[ParametricPlot3D[{{Cos[\[Alpha] t], Sin[\[Alpha] t], 
Sqrt[1 - \[Alpha]^2] t}, {Cos[\[Alpha] t], 
Sin[\[Alpha] t], -Sqrt[1 - \[Alpha]^2] t}}, {\[Alpha], -1, 1}, 
PlotRange -> {{-1, 1}, {-1, 1}, {-2 \[Pi], 2 \[Pi]}}], {t, 0, 
2 \[Pi]}, AnimationRunning -> False]

But I'm struggling to incorporate the cylinder itself:

Graphics3D[Cylinder[{{0, 0, -2 \[Pi]}, {0, 0, 2 \[Pi]}}, 1]]

You can probably see the problem: the curves run around an invisible cylinder. I'd be much happier if I could see it! I've tried to squeeze the cylinder in in a few different ways (putting it into the Animate[ParametricPlot3D[...]] in different places, and using Epilog), but no luck. Any suggestions?

Answer 1

I think the simplest way is to include a Show:

Animate[
  Show[
    ParametricPlot3D[{{Cos[\[Alpha] t], Sin[\[Alpha] t], 
      Sqrt[1 - \[Alpha]^2] t}, {Cos[\[Alpha] t], 
      Sin[\[Alpha] t], -Sqrt[1 - \[Alpha]^2] t}}, {\[Alpha], -1, 1}, 
    PlotRange -> {{-1, 1}, {-1, 1}, {-2 \[Pi], 2 \[Pi]}}], 

    Graphics3D[Cylinder[{{0, 0, -2 \[Pi]}, {0, 0, 2 \[Pi]}}, 1]]
  ], 
{t, 0, 2 \[Pi]}, AnimationRunning -> False]

Show returns a graphics object that can be further customized in a similar way to ParametricPlot3D.

EDIT I really liked the animation, but think the Cylinder by default masks the function. Perhaps the following is easier to see:

Animate[
  Show[
    ParametricPlot3D[{{Cos[\[Alpha] t], Sin[\[Alpha] t], 
      Sqrt[1 - \[Alpha]^2] t}, {Cos[\[Alpha] t], 
      Sin[\[Alpha] t], -Sqrt[1 - \[Alpha]^2] t}}, {\[Alpha], -1, 1}, 
      PlotRange -> {{-1, 1}, {-1, 1}, {-2 \[Pi], 2 \[Pi]}}, 
      Axes -> False, BoxStyle -> Opacity[0]], 
    Graphics3D[{EdgeForm[None], Yellow, Opacity[0.2], 
      Cylinder[{{0, 0, -2 \[Pi]}, {0, 0, 2 \[Pi]}}, 1]}]
  ], 
{t, 0, 2 \[Pi]}, AnimationRunning -> False]