Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

I need to calculate a limit of a sequence given by its recurrence relation. I tried the following:

Limit[DifferenceRoot[Function[{y, n}, {
      - n (1 + n)^2 (5 + 2 n) y[n] 
      - (1 + n) (3 + n) (11 + 14 n + 4 n^2) y[1 + n] 
      + (-77 - 128 n - 69 n^2 - 12 n^3) y[2 + n] 
      + (29 + 84 n + 79 n^2 + 30 n^3 + 4 n^4) y[3 + n] 
      + (3 + n)^3 (3 + 2 n) y[4 + n] == 0, 
      y[1] == 0, y[2] == -1, y[3] == 1/8, y[4] == -215/216
  }]][n], n -> Infinity]

but it returned unevaluated.

share|improve this question
add comment

1 Answer

First, you can try to apply the FunctionExpand command to the DifferenceRoot object. If it is able to find a closed form of the sequence, then the Limit might be able to find an exact symbolic limit.

To find a numerical approximation, you can use the SequenceLimit command. In general, it does not guarantee to give the correct result, but if your sequence behaves 'nicely' then you might be able to obtain the correct result with a very high precision:

In[1]:= SequenceLimit[N[Table[
        DifferenceRoot[Function[{y, n}, {
            - n (1 + n)^2 (5 + 2 n) y[n] 
            - (1 + n) (3 + n) (11 + 14 n + 4 n^2) y[1 + n] 
            + (-77 - 128 n - 69 n^2 - 12 n^3) y[2 + n] 
            + (29 + 84 n + 79 n^2 + 30 n^3 + 4 n^4) y[3 + n] 
            + (3 + n)^3 (3 + 2 n) y[4 + n] == 0, 
            y[1] == 0, y[2] == -1, y[3] == 1/8, y[4] == -215/216
        }]][n],
    {n, 1, 500}], 200]]

Out[1]= -0.442460189377912495218798219174656335184133627022583585864263293471236392630861

Plugging the numeric result in the TranscendentalRecognize function with a wide enough set of transcendental constants, you might get its possible closed form:

-1/12 (-π^2 Log[2] + 4 Log[2]^3 + 9 Zeta[3])
share|improve this answer
add comment

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.