Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.
Sum[Sin[n*x]*Sin[n] /. x -> 1, {n, 1, Infinity}] == 
  Sum[Sin[n*x]*Sin[n], {n, 1, Infinity}] /. x -> 1

Sum::div: Sum does not converge. >>

Sum::div: Sum does not converge. >>

Sum[Sin[n]^2, {n, 1, Infinity}] == 0

Can anyone explain this? I do not understand why Sum[Sin[n*x]*Sin[n], {n, 1, Infinity}] is automatically simplified to 0 when the series does not converge (unless Mod[x, Pi] == 0 in which case the sum really is zero).

share|improve this question
    
although this sum is wrong the partial sum given by Mathematica are correct. I have tested this sum with wolfram alpha and it gave me that it diverges so I assume that at v9 they have corrected it ... –  Spawn1701D Apr 21 '13 at 5:16
1  
No, same response from v9. –  fairflow Apr 21 '13 at 5:29

1 Answer 1

The reason is you hit a distribution.

partialSum = Sum[Sin[n*x]*Sin[n], {n, 1, bigN}];
(*  1/4 Csc[(1 + x)/2] Sin[1/2 (-1 - 2 bigN - x - 2 bigN x)] 
   -1/4 Csc[(1 - x)/2] Sin[1/2 (-1 - 2 bigN + x + 2 bigN x)] *)

and you can immediately see from here (7th from the top) that in the limit bigN->Infinity you get the sum of two Dirac functions centered at -1 and +1.

So we can conclude that

Sum[Sin[n*x]*Sin[n], {n, 1, Infinity}] = -Pi/2 DiracDelta[x+1] + Pi/2 DiracDelta[x-1]

Another way to check this (not a full proof) is to make the sum convergent :

convSum =  Sum[Sin[n*x]*Sin[n] Exp[-eps n], {n, 1, Infinity}, Assumptions :> {eps > 0}];

result = FullSimplify[ComplexExpand[convSum, TargetFunctions -> {Re, Im}]]
(* (Sin[1] Sin[x] Sinh[eps])/
   (1 + Cos[2] + Cos[2 x] - 4 Cos[1] Cos[x] Cosh[eps] + Cosh[2 eps]) *)

Plot3D[result, {x, -2, 2}, {eps, 0, 1}, PlotRange -> All]

plot

Limit[result, eps -> 0]
(* 0 *)

but :

Limit[result /. x -> -1, eps -> 0]
(* -Infinity *)

Limit[result /. x -> 1, eps -> 0]
(* Infinity *)
share|improve this answer

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.