# Using Mathematica to find poles of Gamma functions

I am concerned about the expression on the RHS of equation A.5 (page 19) in this paper:

$$\int\frac{d^d q}{(q^2)^{\nu_1}[(\vec{k}-\vec{q})^2]^{\nu_2}}=\frac{\Gamma(d/2-\nu_1)\Gamma(d/2-\nu_2)\Gamma(\nu_1+\nu_2-d/2)}{\Gamma(\nu_1)\Gamma(\nu_2)\Gamma(d/2-\nu_1-\nu_2)}\pi^{d/2}k^{d-2\nu_1-2\nu_2}$$

• Can I use Mathematica to find a Laurent kind of expansion of the RHS in the limit of $d-3 = \epsilon \rightarrow 0$? I would guess that it has poles in $\epsilon$ and I would like to know the residues.

• And could I have used Mathematica to do this integral and give me the value as stated in equation A.5?

-
the first step would (or could) be to go to hyperspherical coordinates. not sure if mathematica can do this automatically. what have you tried so far? –  acl Mar 21 '13 at 2:13
What does $d-3=e\rightarrow 0$ mean? –  hhh Mar 21 '13 at 2:26
as for your second question, did you try Series? –  acl Mar 21 '13 at 2:57
I presume that the limit on d simply means $d=\epsilon+3$ and letting $\epsilon\rightarrow 3$. –  Jonathan Shock Mar 21 '13 at 10:14
@JonathanShock $\epsilon\rightarrow 0$ more likely –  acl Mar 21 '13 at 11:02

You could teach Mathematica about the poles of $\Gamma$ (it can already compute the residues). This is done with a "divisor" object in mathematics, defined to be an integral linear combination of the zeros and poles (positive for the zeros, negative for the poles). The following implementation computes its coefficients for products and quotients of Gamma functions. It really only needs to know that $\Gamma$ has simple poles at all non-positive integers (which is on the first line of the definition); the rest tells it how to decompose the products and powers (which includes quotients, which are $-1$ powers):

divisor[Gamma[x_]] := -Boole[x <= 0 && x \[Element] Integers];
divisor[Times[x_, y__]] := divisor[Times[x]] + divisor[Times[y]];
divisor[Power[x_Gamma, n_Integer]] := n divisor[x];
divisor[x_] := 0 (* Everything else, for now *)


Let's encapsulate the right hand side of the integral equation in the question:

f[d_, n1_, n2_] := Gamma[d/2 - n1] Gamma[d/2 - n2] Gamma[n1 + n2 - d/2] /
(Gamma[n1] Gamma[n2] Gamma[d/2 - n1 - n2])


I will assume that $\nu_1$ and $\nu_2$ are positive integers in the following calculation, which characterizes the points where $f$ might have a pole:

FullSimplify[Reduce[divisor[f[d, n1, n2]] < 0, d],
Assumptions -> n1 \[Element] Integers && n2 \[Element] Integers && n1 > 0 && n2 > 0]


$\left(-\frac{d}{2}\in \text{Integers}\&\&d>2 (\text{n1}+\text{n2})\right)\|\left(\left(\frac{d}{2}\left|\frac{d}{2}\right|\frac{d}{2}\right)\in \text{Integers}\&\&(d\leq 2 \text{n1}\|\text{n1}>\text{n2})\&\&(d\leq 2 \text{n2}\|\text{n1}\leq \text{n2})\right)$

Although that's a little redundant, it's readable: there are indeed poles wherever $d/2$ is integral and does not exceed the larger of $\nu_1$ and $\nu_2$ or exceeds their sum. We may compute the residues at such points using Residue. Here is a bunch of them computed at once for a particular choice of $\nu_1$ and $\nu_2$ to illustrate the previous result:

With[{n1 = 2, n2 = 1}, Residue[f[d, n1, n2], {d, #}] & /@ Range[-2, 8]]


$\{-24, 0, 12, 0, -4, 0, 0, 0, 0, 4\}$

If other assumptions need to be made about $d$, $\nu_1$, or $\nu_2$, modify the assumptions in Reduce and FullSimplify accordingly.

-
in Dimensional regularization d is never really integral. I somehow think that this question is off-topic here and should be moved to a physics site. –  Rolf Mertig Mar 21 '13 at 22:56
@RolfMertig I agree, but am wondering what the others think –  acl Mar 21 '13 at 23:06
@Rolf The question asks, if I may have the temerity to quote it literally, "Can I use Mathematica to find ... poles ... and I would like to know the residues." That seems on topic here and would be of interest regardless of whether or not $d$ is integral, or will approach an integer in a limit. In dimensional regularization it appears that the poles near integers would be of interest, regardless of $d$, because the behavior of a meromorphic function is completely determined by its behavior at its poles: therein lies the power of the technique. –  whuber Mar 22 '13 at 0:21

Of course there are no poles, which you can check like this:

    int[n1_,n2_] = (Gamma[d/2 - n1]*Gamma[d/2 - n2]*Gamma[-(d/2) + n1 + n2])/
(Gamma[n1]*Gamma[d/2 - n1 - n2]*Gamma[n2]);
res[n1_, n2_,simp_:Identity] := Collect[ Normal[Series[int[n1,n2] /.
d->(e+3),{e, 0, 1}]], e,simp];

res[1, 1, FullSimplify]


gives

and

TraditionalForm[res[Subscript[\[Nu], 1], Subscript[\[Nu], 2]]] /.
e :> Style[\[Epsilon], 42, Red]


results in

and no, there is no straighforward way to use Integrate to do a d-dimensional integrals. Also there is usually no need since you do learn how to this in your Quantum Field Theory course (or look it up in the literature).

-
What assumptions are you making about $\nu_1$, $\nu_2$, and $d$? Because $\Gamma$ has simple poles at $0$ and all negative integers, in general the right hand side in the question has countably many poles as a function of any (or all) of these three variables. (Frankly, I can't make any sense of the question at all, so I'm not challenging your answer: I would just like to understand what you're really claiming.) –  whuber Mar 21 '13 at 15:42
@Rolf Mertig The analytically continued Gamma function has poles at any negative integral value of its argument. At $-n$ ($n \in \mathbb{Z}^+$) $\Gamma[-n]$ has the residue $\frac{(-1)^n}{n!}$. I want to know how to get Mathematica to do this analysis on the value of the integral. –  Anirbit Mar 21 '13 at 19:58
I assumed nu1 and nu2 to be integers, right? –  Rolf Mertig Mar 21 '13 at 19:59
@Rolf Mertig Yes. $\nu1$ and $\nu2$ are always integers. –  Anirbit Mar 21 '13 at 20:47